//+------------------------------------------------------------------+
//|                                             S1_Ignicao1_v4_2.mq5 |
//|                                                  DESENVOLVIMENTO |
//|                                                           OXFORD |
//|                                             HEDGING HORN CAPITAL |
//|                                     https://www.hhcapital.com.br |
//+------------------------------------------------------------------+
#property copyright "Copyright 2022, HEDGING HORN CAPITAL"
#property link      "https://www.hhcapital.com.br"
#property version   "DESENV_v4_2"
#property description "HFT MARKET MAKING BASED ON OXFORD'S STUDIES. MINI INDICE."

//+===================================================================================================================================================================================+
//| 0 - SESSAO DE CABECALHO / ADMISSAO                                                                                                                                                
//+===================================================================================================================================================================================+
//+------------------------------------------------------------------+
//| 0.1 - IMPORTACOES                                                |
//+------------------------------------------------------------------+
#include <Expert/Expert.mqh>
#include <Trade/Trade.mqh>
#include <Trade/SymbolInfo.mqh>
#include "MarketBook.mqh"
#include "S0_Admissao1_v4_2.mqh"
#include "S2_Motor1_v4_2.mqh"
#include "S3_Freios1_v4_2.mqh"
#include "S4_Cambio4x4_v4_2.mqh"
#include "S5_Direcao1_v4_2.mqh"
#include "S6_Transmissao1_v4_2.mqh"
//
//+------------------------------------------------------------------+
//| 0.2 - ENTRADAS DE USUARIO                                        |
//+------------------------------------------------------------------+
//+------------------------------------------------------------------+
//| 0.2.1 - INPUTS DE GERENCIAMENTO DE INVENTARIO                    |
//+------------------------------------------------------------------+
input group          "Gerenciamento de Inventário---------------|---------------------------------------------------------------"
input int            niveis = 4;                               //η: Quantidade de níveis máximos η {1}[1, +inf[
input int            rajada = 1;                               //r: Quantidade por ordem r {1}[1, +inf[

//+------------------------------------------------------------------+
//| 0.2.2 - INPUTS DE GERENCIAMENTO DE ESTRATEGIA                    |
//+------------------------------------------------------------------+
input group          "Gerenciamento de Estratégia---------------|---------------------------------------------------------------"
input double         fi = 0.0002;                              //φ: Running Penalty (injeção eletrônica)
input double         passoFi = 10;                             //passo φ
input double         custoOperacao = 1.20;                     //c: Custo por operacao c {0.88} [0.0, 2.0[
input int            profundidadeBook = 5;                     //β: Profundidade do book a calcular o k {5}[1, +inf[
input double         desvioDiario = 8;                         //σ: Desvios padroes limite para o preco do ativo no dia
input int            lifetimeOrdem = 120;                      //τO: Tempo em seg da duracao de uma ordem pendente
input int            lifetimePosicao = 500;                    //τP: Tempo em seg da duracao de uma posicao pendente
input int            intervaloTicks = 1000;                    //Ticks: Intervalo de ticks do ArrayTick
input int            periodosDesvio = 10;                      //nD: Quantidade de periodos em min de desvio padrao
input double         eta = 0.001;                              //η: Param positivo relacionado a aceleracao
input double         dzeta = 0.5;                              //ζ: Param positivo relacionado a velocidade
//+------------------------------------------------------------------+
//| 0.2.3 - INPUTS DE GERENCIAMENTO DE RISCOS                        |
//+------------------------------------------------------------------+
input group          "Gerenciamento de Riscos-------------------|---------------------------------------------------------------"
input double         alvoPercentual = 0.20;                    //XAlvo%: em formato 0.05 = 5% {0.10} [0, inf+[
input double         stopPercentual = 0.10;                    //XStop%: em formato 0.05 = 5% {0.10} [0, 1]
input double         saldoInicial = 4000;                      //X0: Saldo inicial do dia
input double         alvoFinanceiro = 500.0;                   //χsup: 3º Order Risk M.: Alvo financeiro no dia sup(Χ)
input double         stopFinanceiro = -500.0;                  //χinf: 3º Order Risk M.: Stop financeiro no dia inf(Χ)

//+------------------------------------------------------------------+
//| 0.2.4 - INPUTS DE GERENCIAMENTO DE TEMPO                         |
//+------------------------------------------------------------------+
input group          "Gerenciamento de Tempo--------------------|---------------------------------------------------------------"
input ushort         horarioShort_inicial = 545;               //t0: Horário inicial 09:15 -> Τ0 em minutos {600}[600, 985]
input ushort         horarioShort_final = 980;                 //tf: Horário final 16:20 -> ΤF em minutos {700}[600, 985]
input ushort         horarioShort_fechamento = 985;            //Tf: Horário limite de after 16:25 ->ΤP em minutos{705}[600,990]

//+------------------------------------------------------------------+
//| 0.2.5 - INPUTS DE GERENCIAMENTO DE OPERACOES                     |
//+------------------------------------------------------------------+
input group          "Gerenciamento de Operações----------------|---------------------------------------------------------------"

input bool           chaveLambda = false;                      //Chave on/off do lambda {true}
input bool           chaveBook = false;                        //Chave on/off do book {true}
input bool           chaveSpreadDesvio = true;                 //Chave on/off do spread com desvio padrao {true}
input bool           chaveSpreadTend = true;                   //Chave on/off do spread com drift de tendencia {true}
input bool           chaveFiAutomatico = false;                //Chave on/off do fi automatico {false}
input bool           chaveTempoOrdemAuto = true;               //Chave on/off do To relativo ao tamanho do spread {false}  
input bool           chaveEscalonador = true;                  //Chave on/off do escalonador de saldo, alvo, stop do dia {true}
input bool           chaveRiscoSaldo = true;                   //Chave on/off do risco saldo {true}
input bool           chaveRiscoTend = false;                   //Chave on/off do risco de tendencia {true}
input bool           chaveDeinitOrdens = false;                //Chave on/off do cancelamento de ordens no Deinit {false}
input bool           chaveDeinitPosicoes = false;              //Chave on/off do fechamento de posicoes no Deinit {false}


//+------------------------------------------------------------------+
//| 1.3 - VARIAVEIS GLOBAIS                                          |
//+------------------------------------------------------------------+
//+------------------------------------------------------------------+
//| 1.3.1 - OBJETOS   OPERACIONAIS                                   |
//+------------------------------------------------------------------+

operacao             Operacao;
fluido               Fluidos;
slot                 SlotsC[];
slot                 SlotsV[];
MqlTick              ArrayTick[];
MqlBookInfo          ArrayBook[];
CMarketBook          Book(_Symbol);


//+===================================================================================================================================================================================+
//| 1 - SESSAO DE DAR A PARTIDA E CONTROLA EVENTOS / IGNICAO                                                                                                                            
//+===================================================================================================================================================================================+
//+------------------------------------------------------------------+
//| 1.1 - FUNCAO DE INICIALIZACAO                                    |
//+------------------------------------------------------------------+
int OnInit()
{
   Print("DESENVOLVIMENTO V4_2_alterado3");
   
   //INICIALIZA FLUIDOS E OPERACAO
   Fluidos.q = 0;
   Fluidos.t = 0;
   Fluidos.T = lifetimeOrdem;
   Fluidos.t0d = horarioShort_inicial;
   Fluidos.td = 0;
   Fluidos.Td = horarioShort_final;
   Fluidos.nBook = profundidadeBook;
   Fluidos.iBid0 = -1;
   Fluidos.iAsk0 = -1;
   Fluidos.iSlot = 0;
   Fluidos.niveis = niveis;
   Fluidos.rajada = rajada;
   Fluidos.lifetimeOrdem = lifetimeOrdem;
   Fluidos.lifetimePosicao = lifetimePosicao;
   Fluidos.handlerMA = -1;
   Fluidos.handlerSTDDEV = -1;
   Fluidos.periodoMA = 2;
   Fluidos.periodoSTDDEV = periodosDesvio;     
   Fluidos.intervaloTicks = intervaloTicks;
   Fluidos.limiteInfDesvio = 0;
   Fluidos.limiteSupDesvio = 500;
   Fluidos.lC = 1;
   Fluidos.lV = 1;
   Fluidos.media = -1;
   Fluidos.midPrice = -1;
   Fluidos.sigmaHFT = -1;
   Fluidos.sigmaLFT = -1;
   Fluidos.assimetria = 0.0;
   Fluidos.curtose = 0.0;
   Fluidos.driftLFTTend = 0.0;
   Fluidos.driftLFTVol = 0.0;
   Fluidos.driftHFTVol = 0.0;
   Fluidos.driftHFTTend = 0.0;
   Fluidos.aceleracao = 0.0;
   Fluidos.spreadLFTC = 0.0;
   Fluidos.spreadLFTV = 0.0;
   Fluidos.spreadHFTC = 0.0;
   Fluidos.spreadHFTV = 0.0;
   Fluidos.KC = 100;
   Fluidos.KV = 100;
   Fluidos.lambdaC = 15;
   Fluidos.lambdaV = 10;
   Fluidos.lobC = 0.0;
   Fluidos.lobV = 0.0;
   Fluidos.fi = fi;
   Fluidos.fiInicial = fi;
   Fluidos.passoFi = passoFi;
   Fluidos.c = custoOperacao/1000;
   Fluidos.desvioDiario = desvioDiario;
   Fluidos.precoMedioC = 0.0;
   Fluidos.precoMedioV = 0.0;
   Fluidos.tickMin = 5;
   Fluidos.precoAbertura = -1;
   Fluidos.desvioDiario = desvioDiario;
   Fluidos.limiteInfTend = -1;
   Fluidos.limiteSupTend = -1;
   Fluidos.limiteInfDesvio = -1;
   Fluidos.limiteSupDesvio = -1;
   Fluidos.a = 0.0;
   Fluidos.eC = 0.0;
   Fluidos.eV = 0.0;
   Fluidos.eta = eta;
   Fluidos.dzeta = dzeta;
   if(chaveEscalonador == true) Fluidos.rajada = floor(AccountInfoDouble(ACCOUNT_BALANCE)/10000) + 1;
   if(chaveEscalonador == true) Fluidos.niveis = floor(AccountInfoDouble(ACCOUNT_BALANCE)/(Fluidos.rajada*1000));
   Fluidos.Q = Fluidos.rajada * Fluidos.niveis;
   Operacao.chaveLambda = chaveLambda;
   Operacao.chaveBook = chaveBook;
   Operacao.chaveSpreadDesvio = chaveSpreadDesvio;
   Operacao.chaveSpreadTend = chaveSpreadTend;
   Operacao.chaveFiAutomatico = chaveFiAutomatico;
   Operacao.chaveTempoOrdemAuto = chaveTempoOrdemAuto;
   Operacao.chaveEscalonador = chaveEscalonador;
   Operacao.chaveRiscoSaldo = chaveRiscoSaldo;
   Operacao.chaveRiscoTend = chaveRiscoTend;
   Operacao.chaveDeinitOrdens = chaveDeinitOrdens;
   Operacao.chaveDeinitPosicoes = chaveDeinitPosicoes;
   Operacao.magic = 11111;
   Operacao.diaAtual = 0;
   Operacao.posicoes_total_prev = 0;
   Operacao.posicoes_total = 0;
   Operacao.horarioShort_atual =0;
   Operacao.horarioShort_inicial = horarioShort_inicial;
   Operacao.horarioShort_final = horarioShort_final;
   Operacao.horarioShort_fechamento = horarioShort_fechamento;
   Operacao.travaSaldo = 0;
   Operacao.travaFechaDia = 0;
   Operacao.saldoInicialDia = saldoInicial; 
   Operacao.saldoAtualDia = 0.0;
   Operacao.diferencaSaldo = 0.0;
   Operacao.alvoFinanceiro = alvoFinanceiro;
   if(stopFinanceiro > 0) Operacao.stopFinanceiro = -1*stopFinanceiro;
   else Operacao.stopFinanceiro = stopFinanceiro;
   Operacao.alvoPercentual = alvoPercentual;
   Operacao.stopPercentual = stopPercentual;
   Operacao.stopFinanceiro = stopFinanceiro;
   Operacao.lifetimePosicao = lifetimePosicao;
   Operacao.saldoInicialDia = saldoInicial;
   Operacao.diaPrev = 0;
   Operacao.numeroContratos = 0;
   
   //INICIALIZA O DIA ATUAL
   TimeToStruct(TimeCurrent(), Operacao.horarioMQL_atual);
   Operacao.diaAtual = Operacao.horarioMQL_atual.day;
   
   //INICIALIZA O MARKET BOOK
   if(Operacao.chaveBook == true) if(!MarketBookAdd(_Symbol)) Print("Falha para inicializar o book");
   
   ArrayResize(ArrayTick, Fluidos.intervaloTicks, 0);
   
   //INICIALIZA O ARRAY TICK
   if(CopyTicks(_Symbol, ArrayTick, COPY_TICKS_ALL, 0, Fluidos.intervaloTicks) != -1) 
   {
      ArraySetAsSeries(ArrayTick, true);
   }
   else Print("Falha para inicializar o ArrayTicks: ", GetLastError());
   
   //INICIALIZA O TAMANHO DOS ARRAYS DE SLOTS
   ArrayResize(SlotsC, Fluidos.niveis);
   ArrayResize(SlotsV, Fluidos.niveis);
   
   //INICIALIZA OS SLOTS DE COMPRA E VENDA
   for(int i=0; i<Fluidos.niveis ;i++)
   {
      SlotsC[i].statusCambio = 0;
      SlotsC[i].statusMotor = 0;
      SlotsV[i].statusCambio = 0;
      SlotsV[i].statusMotor = 0;
      SlotsC[i].ponta = 0;
      SlotsV[i].ponta = 2;
   }
   
   //INICIALIZA OS BUFFERS DE MEDIA E DESVIO PADRAO
   Fluidos.handlerMA = iMA(_Symbol, PERIOD_M1, Fluidos.periodoMA, 0, MODE_EMA, PRICE_MEDIAN);
   Fluidos.handlerSTDDEV = iStdDev(_Symbol, PERIOD_M1, Fluidos.periodoSTDDEV, 0, MODE_EMA, PRICE_MEDIAN);
   ArraySetAsSeries(Fluidos.MA, true);
   ArraySetAsSeries(Fluidos.STDDEV, true);
   CopyBuffer(Fluidos.handlerMA, 0, 0, 3, Fluidos.MA);
   CopyBuffer(Fluidos.handlerSTDDEV, 0, 0, 3, Fluidos.STDDEV);
   Fluidos.media = Fluidos.MA[0];
   Fluidos.sigmaHFT = MathAbs(Fluidos.STDDEV[0]);
   Fluidos.driftHFTTend = Fluidos.MA[0] - Fluidos.MA[1];
   Fluidos.driftHFTVol = Fluidos.STDDEV[0] - Fluidos.STDDEV[1];
   Fluidos.aceleracao = log( 1 / exp(Fluidos.driftHFTTend) );
   
     
   return(INIT_SUCCEEDED);
}

//+------------------------------------------------------------------+
//| 1.2 - FUNCAO EVENTO TICK / CORACAO                               |
//+------------------------------------------------------------------+
void OnTick()
{  
   //VERIFICA SE ESTA EM SESSAO DE TRADE OU DE FECHAMENTO
   if(VerificaHorarioOrdens(Operacao)) 
   {
      AtualizaVariaveis();
      FazTrades(Operacao, Fluidos, SlotsC, SlotsV, ArrayTick, ArrayBook);
   }
   else if(VerificaHorarioFechamento(Operacao))
   {
      if(Operacao.travaFechaDia == 0)
      {
         FechaPosicoes(Operacao);
         //Print("Mandou fechar todas as posicoes por fechamento de dia.");
         CancelaOrdensAbertas(Operacao);
         //Print("Mandou cancelar todas as ordens abertas por fechamento de dia.");

         //FECHOU O DIA, DESTRAVA SALDO E SET TRAVA FECHA DIA PARA TRUE
         Operacao.travaSaldo = 0;
         if((PositionsTotal() + OrdersTotal()) == 0) Operacao.travaFechaDia = 1;
      }
      
   }
   else return;
   
   return;
}

//+------------------------------------------------------------------+
//| 1.3 - FUNCAO QUE ATUALIZA AS VARIAVEIS IMPORTANTES               |
//+------------------------------------------------------------------+
void AtualizaVariaveis()
{
   //ATUALIZA O DIA ATUAL
   Operacao.diaAtual = Operacao.horarioMQL_atual.day;
   
   //ATUALIZA O SALDO INICIAL DO DIA PARA BACKTEST
   if(Operacao.chaveEscalonador == true)
   {
      //ESCALONA OS NIVEIS E RAJADA PARA O TAMANHO DE SALDO
      Fluidos.rajada = floor(AccountInfoDouble(ACCOUNT_BALANCE)/10000) + 1;
      Fluidos.niveis = floor(AccountInfoDouble(ACCOUNT_BALANCE)/(Fluidos.rajada*1000));
      Fluidos.Q = Fluidos.rajada * Fluidos.niveis;
      ArrayResize(SlotsC, Fluidos.niveis);
      ArrayResize(SlotsV, Fluidos.niveis);
      
      //PRIMEIRO TICK DO DIA
      if(Operacao.diaAtual != Operacao.diaPrev)
      {        
         if(Operacao.travaSaldo == 0)
         {
            Operacao.saldoInicialDia = AccountInfoDouble(ACCOUNT_BALANCE);
            Operacao.alvoFinanceiro = Operacao.saldoInicialDia * Operacao.alvoPercentual;
            if(Operacao.stopPercentual > 0) Operacao.stopFinanceiro = Operacao.saldoInicialDia * -1 * Operacao.stopPercentual;
            else Operacao.stopFinanceiro = Operacao.saldoInicialDia * Operacao.stopPercentual;
            Operacao.travaSaldo = 1;
            Operacao.travaFechaDia = 0;
            Fluidos.lC = 1;
            Fluidos.lV = 1;
         }
         
         //ZERA OS SLOTS DE COMPRA E VENDA
         for(int i=0;i<Fluidos.niveis;i++)
         {
            SlotsC[i].statusCambio = 0;
            SlotsC[i].statusMotor = 0;
            SlotsV[i].statusCambio = 0;
            SlotsV[i].statusMotor = 0;
         }
      }
   }
   else
   {
      if(Operacao.diaAtual != Operacao.diaPrev)
      {        
         if(Operacao.travaSaldo == 0)
         {
            Operacao.saldoInicialDia = AccountInfoDouble(ACCOUNT_BALANCE);
            Operacao.diaPrev = Operacao.diaAtual;
            Operacao.travaSaldo = 1;
            Operacao.travaFechaDia = 0;
         }
      }
   }
   
   Fluidos.precoAbertura = iOpen(_Symbol, PERIOD_D1, 0);
   
   //ATUALIZA O HORARIO ATUAL
   TimeToStruct(TimeCurrent(), Operacao.horarioMQL_atual);
   
   //ATUALIZA O BOOK
   if(!Operacao.simbolo.RefreshRates()) return;

   if(Operacao.chaveBook == true)
   {
      if(MarketBookGet(_Symbol, ArrayBook))
      {
         //ATUALIZA OS INDICES DO TOPO DO BOOK
         Fluidos.iBid0 = Book.InfoGetInteger(MBOOK_BEST_BID_INDEX);
         Fluidos.iAsk0 = Book.InfoGetInteger(MBOOK_BEST_ASK_INDEX);
      }
      else
      {
         Print("Falha ao atualizar o Book");
      }
   }
   
   //ATUALIZA O ARRAY TICKS
   ArrayResize(ArrayTick, Fluidos.intervaloTicks, 0);
   if(CopyTicks(Symbol(), ArrayTick,COPY_TICKS_ALL, 0, Fluidos.intervaloTicks) != -1) ArraySetAsSeries(ArrayTick, true);
   else Print("Falha para inicializar o ArrayTicks: ", GetLastError());   
   
   //ATUALIZA OS BUFFERS DE MEDIA E DESVIO PADRAO
   CopyBuffer(Fluidos.handlerMA, 0 , 0, 3, Fluidos.MA);
   CopyBuffer(Fluidos.handlerSTDDEV, 0, 0, 3, Fluidos.STDDEV);
   Fluidos.midPrice = (Operacao.simbolo.Ask() + Operacao.simbolo.Bid())/2;
   Fluidos.media = Fluidos.MA[0];
   Fluidos.sigmaHFT = MathAbs(Fluidos.STDDEV[0]);
   Fluidos.driftHFTTend = Fluidos.MA[0] - Fluidos.MA[1];
   Fluidos.driftHFTVol = Fluidos.STDDEV[0] - Fluidos.STDDEV[1];
   if(Fluidos.MA[1] - Fluidos.MA[2] != 0) Fluidos.aceleracao = (Fluidos.MA[0] - Fluidos.MA[1])/(Fluidos.MA[1] - Fluidos.MA[2]);
   
   //ATUALIZA QUANTIDADE E HORARIO td
   Fluidos.q = AtualizaQuantidade(Operacao, Fluidos);
   Fluidos.td = Operacao.horarioMQL_atual.hour*60 + Operacao.horarioMQL_atual.min;
   
   //ATUALIZA OS SLOTS
   for(int i=0; i<Fluidos.niveis ;i++)
   {
      SlotsC[i].ponta = 0;
      SlotsV[i].ponta = 2;
   }
   
   return;
}

//+------------------------------------------------------------------+
//| 1.4 - FUNCAO EVENTO BOOK                                         |
//+------------------------------------------------------------------+
void OnBookEvent(const string &symbol)
{
   if(Operacao.chaveBook == true)
   {
     //ATUALIZA OS INDICES DO TOPO DO BOOK
      if(MarketBookGet(_Symbol, ArrayBook))
      {
         Fluidos.iBid0 = Book.InfoGetInteger(MBOOK_BEST_BID_INDEX);
         Fluidos.iAsk0 = Book.InfoGetInteger(MBOOK_BEST_ASK_INDEX);
      }
      else
      {
         Print("Falha ao obter o Book");
      } 
   }
   
   return;
}

//+------------------------------------------------------------------+
//| 1.5 - FUNCAO EVENTO TRADE                                        |
//+------------------------------------------------------------------+
void OnTrade()
{

}

//+------------------------------------------------------------------+
//| 1.6 - FUNCAO DE DESLIGAMENTO                                     |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
   //DA RELEASE NOS HANDLERS DE MEDIA E DESVIO PADRAO
   IndicatorRelease(Fluidos.handlerMA);
   IndicatorRelease(Fluidos.handlerSTDDEV);
   
   //CANCELA ORDENS ABERTAS E FECHA POSICOES
   if(Operacao.chaveDeinitOrdens == true)
   {
      CancelaOrdensAbertas(Operacao);
   }
   if(Operacao.chaveDeinitPosicoes == true)
   {
      FechaPosicoes(Operacao);
   }
   Print("Numero de contratos executados: ", Operacao.numeroContratos);
   Print("OUTPUT PATH=",TerminalInfoString(TERMINAL_DATA_PATH));
   
   //RAZAO PARA A DESINICIALIZACAO
   printf("DEINIT REASON: %d", reason);
}

//+===================================================================================================================================================================================+
//| FIM DO PROGRAMA                                                                                                   
//+===================================================================================================================================================================================+