//============================================================================================= MQL5 ===
//    LibreInfoPDO Main_5 v1.004 MQL5
//    Модуль обработки событий
//    LibreCoin (c)2014-2017      
//======================================================================================================
#property strict
//============================================================================================= MQL5 ===
//    INCLUDE - подключаемые модули
//------------------------------------------------------------------------------------------------------
//----- Обратные ссылки на основной файл проекта
#include "LIP_Ref_5_v1.004.mqh"
//============================================================================================= MQL5 ===
//    EVENT PROCESSING MODULE
//------------------------------------------------------------------------------------------------------
//
//============================================================================================= MQL5 ===
//    On_Init()  - инициализация советника
//------------------------------------------------------------------------------------------------------
ENUM_INIT_RETCODE On_Init(){
//----- Счетчики и настройки счетчиков
   gnTick=0;
   gInTimer=false;
//----- Определяем имя программы   
   ProgramName=MQLInfoString(MQL_PROGRAM_NAME);
//----- Рассчитываем короткое имя индикатора   
   ChartID_Str=IntegerToString(ChartID());
   IndicatorShortName=vers+" "+StringSubstr(ChartID_Str,StringLen(ChartID_Str)-3);
   IndicatorSetString(INDICATOR_SHORTNAME,IndicatorShortName);
//----- Глобальные параметры  
   TheSymbol=Symbol();
//----- Настройка массивов
   ArrayResize(inSelectSym,nSymSelectList);  
   ArrayResize(inEliminatSym,nSymEliminatList);  
   ArrayResize(inSelectMag,nMagSelectList);  
   ArrayResize(inEliminatMag,nMagEliminatList);  
   ArrayResize(inSelectTick,nTickSelectList);  
   ArrayResize(inEliminatTick,nTickEliminatList);  
//----- Настройки для отбора по инструменту
   {switch(SelSym)
   {
      case SelSym_all:
         {
            inSelectSym[0]="";
            break;
         }
      case SelSym_curr:
         {
            inSelectSym[0]=TheSymbol;
            break;
         }
      case SelSym_user:
         {
            inSelectSym[0]=SelectorSymbol;
            break;
         }
      case SelSym_but:
         {
            inEliminatSym[0]=SelectorSymbol;
            break;
         }
      case SelSym_list:
         {
            FillSymSelect(inSelectSym);
            break;
         }
      case SelSym_butlist:
         {
            FillSymEliminat(inEliminatSym);
            break;
         }
      case SelSym_listbutlist:
         {
            FillSymSelect(inSelectSym);
            FillSymEliminat(inEliminatSym);
            break;
         }
      default:
         {
            inSelectSym[0]="";
         }
   }}//switch(SelSym)
//----- Настройки для отбора по магику
   {switch(SelMag)
   {
      case SelMag_all:
         {
            inSelectMag[0]=0;
            break;
         }
      case SelMag_user:
         {
            inSelectMag[0]=SelectorMagic;
            break;
         }
      case SelMag_but:
         {
            inEliminatMag[0]=SelectorMagic;
            break;
         }
      case SelMag_list:
         {
            FillMagSelect(inSelectMag);
            break;
         }
      case SelMag_butlist:
         {
            FillMagEliminat(inEliminatMag);
            break;
         }
      case SelMag_listbutlist:
         {
            FillMagSelect(inSelectMag);
            FillMagEliminat(inEliminatMag);
            break;
         }
      default:
         {
            inSelectMag[0]=0;
         }
   }}//switch(SelMag)
//----- Настройки для отбора по тикету
   {switch(SelTick)
   {
      case SelTick_all:
         {
            inSelectTick[0]=0;
            break;
         }
      case SelTick_user:
         {
            inSelectTick[0]=SelectorTicket;
            break;
         }
      case SelTick_but:
         {
            inEliminatTick[0]=SelectorTicket;
            break;
         }
      case SelTick_list:
         {
            FillTickSelect(inSelectTick);
            break;
         }
      case SelTick_butlist:
         {
            FillTickEliminat(inEliminatTick);
            break;
         }
      case SelTick_listbutlist:
         {
            FillTickSelect(inSelectTick);
            FillTickEliminat(inEliminatTick);
            break;
         }
      default:
         {
            inSelectTick[0]=0;
         }
   }}//switch(SelMag)
//----- Настройки таймера
   {if(!MQLInfoInteger(MQL_TESTER))                            //Не тестирование
   { 
      int err=-1;
      int count=50;
      {while((err!=0)&&(count>0))
      {
         ResetLastError();
         EventSetMillisecondTimer(SetMSTimer);                 //Установка таймера XXX миллисекунд
         err=GetLastError();
         {if(err!=0)
         {
            Sleep(50);
            Print("EventSetMillisecondTimer n=",count," err >>",err);
         }}//if(err!=0)
         count--;
      }}//while((err!=0)&&(count>0))
   }}//if(!MQLInfoInteger(MQL_TESTER))
//----- Установка и расчет параметров окна индикатора
   IndicatorSetInteger(INDICATOR_DIGITS,0);
   nSubWindow=ChartWindowFind(0,IndicatorShortName);           //Что странно, ожидалось что будет работать ProgramName
   IndHeigh=ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,nSubWindow);
   IndicatorSetDouble(INDICATOR_MINIMUM,0.0);
   IndicatorSetDouble(INDICATOR_MAXIMUM,IndHeigh);
   nFirstBar=(int)ChartGetInteger(0,CHART_FIRST_VISIBLE_BAR);
   kScale=((ChartGetInteger(0,CHART_WIDTH_IN_PIXELS)>0)        //Расчет масштаба графика (баров на пиксел)
               ?((double)ChartGetInteger(0,CHART_WIDTH_IN_BARS)/ChartGetInteger(0,CHART_WIDTH_IN_PIXELS))
               :(1));
//----- Запрашиваем историю сделок и ордеров за указанный период серверного времени.
   {if(!HistorySelect(0,TimeCurrent()))
   {
      Print("HistorySelect Error!");
      return(INIT_FAILED);
   }}//Если неудачно - выходим
//----- Определение количества ордеров, сделок, позиций. Создание графических объектов.
   nColo=0;                                                    //Счетчик колонок вывода 
//----- Открытые позиции
   {if(PositionsView)
   {
      Positions_Total=PositionsTotal();                        //Текущие позиции
      Sel_Positions_Total=CalcPositionsTotal(inSelectSym,inEliminatSym,SelSym,
                                             inSelectMag,inEliminatMag,SelMag,
                                             inSelectTick,inEliminatTick,SelTick);//Текущие позиции отобранные
      CreateColoLabel("LIP",ColoStep*nColo,
                      "Position="+IntegerToString(Sel_Positions_Total)+"/"+IntegerToString(Positions_Total));//Создаём графический объект заголовка колонки
      CreateColo("LIP",ColoStep*nColo,Positions_Total);        //Создаём графический объект для колонки позиций
      Positions_Total_Old=Positions_Total;                     //Текущие позиции в буфер
      Sel_Positions_Total_Old=Sel_Positions_Total;             //Текущие позиции отобранные в буфер
      nColo++;
   }}//if(PositionsView)
//----- Открытые отложенные ордера
   {if(OrdersView)
   {
      Orders_Total=OrdersTotal();                              //Текущие лимитные ордера
      Sel_Orders_Total=CalcOrdersTotal(inSelectSym,inEliminatSym,SelSym,
                                       inSelectMag,inEliminatMag,SelMag,
                                       inSelectTick,inEliminatTick,SelTick); //Текущие лимитные ордера отобранные
      CreateColoLabel("LIO",ColoStep*nColo,
                      "Order="+IntegerToString(Sel_Orders_Total)+"/"+IntegerToString(Orders_Total));//Создаём графический объект заголовка колонки
      CreateColo("LIO",ColoStep*nColo,Orders_Total);           //Создаём графический объект для колонки ордеров
      Orders_Total_Old=Orders_Total;                           //Текущие лимитные ордера в буфер
      Sel_Orders_Total_Old=Sel_Orders_Total;                   //Текущие лимитные ордера отобранные в буфер
      nColo++;
   }}//if(OrdersView)
//----- Выполненные ордера в истории
   {if(HistoryOrdersView)
   {
      History_Orders_Total=HistoryOrdersTotal();               //Закрытые рыночные ордера
      Sel_History_Orders_Total=CalcHistoryOrdersTotal(inSelectSym,inEliminatSym,SelSym,
                                                      inSelectMag,inEliminatMag,SelMag,
                                                      inSelectTick,inEliminatTick,SelTick);//Закрытые рыночные ордера отобранные
      CreateColoLabel("LHO",ColoStep*nColo,
                      "History_Order="+IntegerToString(Sel_History_Orders_Total)+"/"+IntegerToString(History_Orders_Total));//Создаём графический объект заголовка колонки
      CreateColo("LHO",ColoStep*nColo,History_Orders_Total);   //Создаём графический объект для колонки ордеров в истории
      History_Orders_Total_Old=History_Orders_Total;           //Закрытые рыночные ордера в буфер
      Sel_History_Orders_Total_Old=Sel_History_Orders_Total;   //Закрытые рыночные ордера отобранные в буфер
      nColo++;
   }}//if(HistoryOrdersView)
//----- Сделки в истории
   {if(HistoryDealsView)
   {
      History_Deals_Total=HistoryDealsTotal();                 //Совершенные сделки (выполненные ордера)
      Sel_History_Deals_Total=CalcHistoryDealsTotal(inSelectSym,inEliminatSym,SelSym,
                                                    inSelectMag,inEliminatMag,SelMag,
                                                    inSelectTick,inEliminatTick,SelTick);//Совершенные сделки (выполненные ордера) отобранные
      CreateColoLabel("LHD",ColoStep*nColo,
                      "History_Deal="+IntegerToString(Sel_History_Deals_Total)+"/"+IntegerToString(History_Deals_Total));//Создаём графический объект заголовка колонки
      CreateColo("LHD",ColoStep*nColo,History_Deals_Total);    //Создаём графический объект для колонки сделок в истории
      History_Deals_Total_Old=History_Deals_Total;             //Совершенные сделки (выполненные ордера) в буфер
      Sel_History_Deals_Total_Old=Sel_History_Deals_Total;     //Совершенные сделки (выполненные ордера) отобранные в буфер
      nColo++;
   }}//if(HistoryDealsView)
//-----
   return(INIT_SUCCEEDED);
}//On_Init()
//
//============================================================================================= MQL5 ===
//  On_Tick() - Основной обработчик тиков
//------------------------------------------------------------------------------------------------------
void On_Tick(){
//----- Прерываем загрузку, если индикатор уже есть
   {if((ChartWindowFind(0,IndicatorShortName)>=0)&&(ChartWindowFind(0,ProgramName)>=0))
   {
      Print("Abort loading indicator: ",ProgramName);
      ChartIndicatorDelete(0,ChartWindowFind(0,ProgramName),ProgramName);
   }}//if(ChartWindowFind(0,IndicatorShortName)>=0)
//-----
   //{if(!gInTimer)
   //{
      gnTick++;
   //   gInTimer=false;
   //}}//if(!InTimer)
   {if(gnTick>4294967000)
   {
      gnTick=100;
   }}//if(gnTick>4294967000)
//----- Установка и расчет параметров окна индикатора
   ChartID_Str=IntegerToString(ChartID());
   IndicatorShortName=vers+" "+StringSubstr(ChartID_Str,StringLen(ChartID_Str)-3);
   //ProgramName=MQLInfoString(MQL_PROGRAM_NAME);
   nSubWindow=ChartWindowFind(0,IndicatorShortName);
   IndHeigh=ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,nSubWindow);
   IndicatorSetDouble(INDICATOR_MINIMUM,0.0);
   IndicatorSetDouble(INDICATOR_MAXIMUM,IndHeigh);
   nFirstBar=(int)ChartGetInteger(0,CHART_FIRST_VISIBLE_BAR);
   kScale=((ChartGetInteger(0,CHART_WIDTH_IN_PIXELS)>0)        //Расчет масштаба графика (баров на пиксел)
               ?((double)ChartGetInteger(0,CHART_WIDTH_IN_BARS)/ChartGetInteger(0,CHART_WIDTH_IN_PIXELS))
               :(1));
//----- Запрашиваем историю сделок и ордеров за указанный период серверного времени.
   {if(!HistorySelect(0,TimeCurrent()))
   {
      Print("HistorySelect Error!");
      return;
   }}//Если неудачно - выходим
//----- Определение количества ордеров, сделок, позиций.  Вывод графических объектов.
   nColo=0;                                                    //Счетчик колонок вывода 
//----- Список открытых позиций
   {if(PositionsView)
   {
      Positions_Total=PositionsTotal();                        //Текущие позиции
   {if(!HistorySelect(0,TimeCurrent()))
   {
      Print("HistorySelect Error!");
      return;
   }}//Если неудачно - выходим
      Sel_Positions_Total=CalcPositionsTotal(inSelectSym,inEliminatSym,SelSym,
                                             inSelectMag,inEliminatMag,SelMag,
                                             inSelectTick,inEliminatTick,SelTick);//Текущие позиции отобранные
      {if(Sel_Positions_Total!=Sel_Positions_Total_Old)        //Пересчет - перерисовка при изменении количества
      {
         DeleteColo("LIP",Positions_Total_Old);                //Колонка позиций
         CreateColo("LIP",ColoStep*nColo,Positions_Total);
      }}//if(Sel_Positions_Total!=Sel_Positions_Total_Old)
      MoveColoLabel( "LIP",                                    //Заголовок колонки
                     ColoStep*nColo,
                     "Position="+
                     IntegerToString(Sel_Positions_Total)+"/"+
                     IntegerToString(Positions_Total)+
                     ((SummView)
                        ?(" ="+DoubleToString(CalcPositionsSumm(inSelectSym,inEliminatSym,SelSym,
                                                               inSelectMag,inEliminatMag,SelMag,
                                                               inSelectTick,inEliminatTick,SelTick),2)+" ")
                        :(""))+
                     ""   
                    );
      //-----
      {if(Positions_Total>=0)
      {
         nRow=0;
         CopyTime(TheSymbol,PERIOD_CURRENT,(nFirstBar-(int)((ColoStep*nColo+ColoShift)*kScale)),1,gTime);
         {for(int i=Positions_Total-1;i>=0;i--)
         {
            sTXW="LIP_"+IntegerToString(i);                    //Устанавливаем имя для текcтового объекта
            ObjectSetString(0,sTXW,OBJPROP_TEXT," ");          //Обнуление строки вывода
            ulong Pos_Tick=PositionGetTicket(i);               //Выбираем позицию по номеру в списке
            {if(Pos_Tick<=0){continue;}}                       //Неудачно - следующий
            {if(!CheckSym(PositionGetString(POSITION_SYMBOL),inSelectSym,inEliminatSym,SelSym)){continue;}}//Не тот символ - следующий
            {if(!CheckMag(PositionGetInteger(POSITION_MAGIC),inSelectMag,inEliminatMag,SelMag)){continue;}}//Проверка соответствия магика модели по критерию выбора
            {if(!CheckTick(PositionGetInteger(POSITION_TICKET),inSelectTick,inEliminatTick,SelTick)){continue;}}//Проверка соответствия тикета модели по критерию выбора
            ENUM_POSITION_TYPE OrdType=(ENUM_POSITION_TYPE)PositionGetInteger(POSITION_TYPE);
            TypeStringPos=EnumToString(OrdType);
            StringReplace(TypeStringPos,"POSITION_TYPE_","");
            DataStringPos= "    "+
                           IntegerToString(i)+"."+
                           PositionGetString(POSITION_SYMBOL)+" "+
                           TypeStringPos+" ["+
                           IntegerToString(Pos_Tick)+"-"+
                           IntegerToString(PositionGetInteger(POSITION_MAGIC))+"-"+
                           DoubleToString(PositionGetDouble(POSITION_VOLUME),2)+"-"+
                           DoubleToString(PositionGetDouble(POSITION_PRICE_OPEN),
                                          (int)SymbolInfoInteger(PositionGetString(POSITION_SYMBOL),SYMBOL_DIGITS))+"]="+
                           DoubleToString(PositionGetDouble(POSITION_PROFIT),2)+" "+
                           "";
            ResetLastError();
            {if(!ObjectSetInteger(
                           0,                                  //Идентификатор чарта
                           sTXW,                               //Имя объекта
                           OBJPROP_TIME,                       //Изменяем координату времени объекта
                           gTime[0]
                         ))
            {
               Print("ObjectSetInteger0 Error=",GetLastError());
               continue;
            }}//if(!ObjectSetInteger(...
            ResetLastError();
            {if(!ObjectSetDouble(
                           0,                                  //Идентификатор чарта
                           sTXW,                               //Имя объекта
                           OBJPROP_PRICE,                      //Изменяем координату цены объекта
                           IndHeigh-11*(nRow+1)
                         ))
            {
               Print("ObjectSetDouble0 Error=",GetLastError());
               continue;
            }else{
               nRow++;
            }}//if(!ObjectSetDouble(...
            ObjectSetString(0,sTXW,OBJPROP_TEXT,DataStringPos+"");
         }}//for(int i=Positions_Total-1;i>=0;i--)
      }}//if(Positions_Total>=0)
      //----- Запомним текущие счетчики
      Positions_Total_Old=Positions_Total;                     //Текущие позиции
      Sel_Positions_Total_Old=Sel_Positions_Total;             //Текущие позиции отобранные
      //----- Инкремент счетчика колонок
      nColo++;
   }}//if(PositionsView)
//----- Список открытых отложенных ордеров
   {if(OrdersView)
   {
      Orders_Total=OrdersTotal();                              //Текущие лимитные ордера
      Sel_Orders_Total=CalcOrdersTotal(inSelectSym,inEliminatSym,SelSym,
                                      inSelectMag,inEliminatMag,SelMag,
                                      inSelectTick,inEliminatTick,SelTick); //Текущие лимитные ордера отобранные
      {if(Sel_Orders_Total!=Sel_Orders_Total_Old)              //Пересчет - перерисовка при изменении количества
      {
         DeleteColo("LIO",Orders_Total_Old);                   //Колонка ордеров
         CreateColo("LIO",ColoStep*nColo,Orders_Total);
      }}//if(Sel_Orders_Total!=Sel_Orders_Total_Old)
      MoveColoLabel("LIO",ColoStep*nColo,"Order="+IntegerToString(Sel_Orders_Total)+"/"+IntegerToString(Orders_Total));//Заголовок колонки
      //-----
      {if(Orders_Total>=0)
      {
         nRow=0;
         CopyTime(TheSymbol,PERIOD_CURRENT,(nFirstBar-(int)((ColoStep*nColo+ColoShift)*kScale)),1,gTime);
         {for(int i=Orders_Total-1;i>=0;i--)
         {
            sTXW="LIO_"+IntegerToString(i);                    //Устанавливаем имя для текcтового объекта
            ObjectSetString(0,sTXW,OBJPROP_TEXT," ");          //Обнуление строки вывода
            ulong Ord_Tick=OrderGetTicket(i);                  //Выбираем ордер по номеру в списке
            {if(Ord_Tick<=0){continue;}}                       //Неудачно - следующий
            {if(!CheckSym(OrderGetString(ORDER_SYMBOL),inSelectSym,inEliminatSym,SelSym)){continue;}}//Не тот символ - следующий
            {if(!CheckMag(OrderGetInteger(ORDER_MAGIC),inSelectMag,inEliminatMag,SelMag)){continue;}}//Проверка соответствия магика модели по критерию выбора
            {if(!CheckTick(OrderGetInteger(ORDER_TICKET),inSelectTick,inEliminatTick,SelTick)){continue;}}//Проверка соответствия тикета модели по критерию выбора
            ENUM_ORDER_TYPE OrdType=(ENUM_ORDER_TYPE)OrderGetInteger(ORDER_TYPE);
            TypeStringOrd=EnumToString(OrdType);
            StringReplace(TypeStringOrd,"ORDER_TYPE_","");
            DataStringOrd= "    "+
                           IntegerToString(i)+"."+
                           OrderGetString(ORDER_SYMBOL)+" "+
                           TypeStringOrd+" ["+
                           IntegerToString(Ord_Tick)+"-"+
                           IntegerToString(OrderGetInteger(ORDER_MAGIC))+"-"+
                           DoubleToString(OrderGetDouble(ORDER_VOLUME_CURRENT),2)+"-"+
                           DoubleToString(OrderGetDouble(ORDER_PRICE_OPEN),(int)SymbolInfoInteger(OrderGetString(ORDER_SYMBOL),SYMBOL_DIGITS))+"]"+
                           "";
            ResetLastError();
            {if(!ObjectSetInteger(
                           0,                                  //Идентификатор чарта
                           sTXW,                               //Имя объекта
                           OBJPROP_TIME,                       //Изменяем координату времени объекта
                           gTime[0]
                         ))
            {
               Print("ObjectSetInteger1 Error=",GetLastError());
               continue;
            }}//if(!ObjectSetInteger(...
            ResetLastError();
            {if(!ObjectSetDouble(
                           0,                                  //Идентификатор чарта
                           sTXW,                               //Имя объекта
                           OBJPROP_PRICE,                      //Изменяем координату цены объекта
                           IndHeigh-11*(nRow+1)
                         ))
            {
               Print("ObjectSetDouble1 Error=",GetLastError());
               continue;
            }else{
               nRow++;
            }}//if(!ObjectSetDouble(...
            ObjectSetString(0,sTXW,OBJPROP_TEXT,DataStringOrd+"");
         }}//for(int i=Orders_Total-1;i>=0;i--)
      }}//if(Orders_Total>=0)
      //----- Запомним текущие счетчики
      Orders_Total_Old=Orders_Total;                           //Текущие лимитные ордера
      Sel_Orders_Total_Old=Sel_Orders_Total;                   //Текущие лимитные ордера отобранные
      //----- Инкремент счетчика колонок
      nColo++;
   }}//if(OrdersView)
//----- Список ордеров в истории
   {if(HistoryOrdersView)
   {
      History_Orders_Total=HistoryOrdersTotal();               //Закрытые рыночные ордера
      Sel_History_Orders_Total=CalcHistoryOrdersTotal(inSelectSym,inEliminatSym,SelSym,
                                                     inSelectMag,inEliminatMag,SelMag,
                                                     inSelectTick,inEliminatTick,SelTick);//Закрытые рыночные ордера отобранные
      {if(Sel_History_Orders_Total!=Sel_History_Orders_Total_Old)//Пересчет - перерисовка при изменении количества
      {
         DeleteColo("LHO",History_Orders_Total_Old);           //Колонка истории ордеров
         CreateColo("LHO",ColoStep*nColo,History_Orders_Total);
      }}//if(Sel_History_Orders_Total!=Sel_History_Orders_Total_Old)
      MoveColoLabel("LHO",ColoStep*nColo,"History Order="+IntegerToString(Sel_History_Orders_Total)+"/"+IntegerToString(History_Orders_Total));//Заголовок колонки
      //-----
      {if(History_Orders_Total>=0)
      {
         nRow=0;
         CopyTime(TheSymbol,PERIOD_CURRENT,(nFirstBar-(int)((ColoStep*nColo+ColoShift)*kScale)),1,gTime);
         {for(int i=History_Orders_Total-1;i>=0;i--)
         {
            sTXW="LHO_"+IntegerToString(i);                    //Устанавливаем имя для текcтового объекта
            ObjectSetString(0,sTXW,OBJPROP_TEXT," ");          //Обнуление строки вывода
            ulong Ord_Tick=HistoryOrderGetTicket(i);           //Выбираем ордер по номеру в списке
            {if(Ord_Tick<=0){continue;}}                       //Неудачно - следующий
            {if(!CheckSym(HistoryOrderGetString(Ord_Tick,ORDER_SYMBOL),inSelectSym,inEliminatSym,SelSym)){continue;}}//Не тот символ - следующий
            {if(!CheckMag(HistoryOrderGetInteger(Ord_Tick,ORDER_MAGIC),inSelectMag,inEliminatMag,SelMag)){continue;}}//Проверка соответствия магика модели по критерию выбора
            {if(!CheckTick(HistoryOrderGetInteger(Ord_Tick,ORDER_TICKET),inSelectTick,inEliminatTick,SelTick)){continue;}}//Проверка соответствия тикета модели по критерию выбора
            ENUM_ORDER_TYPE OrdType=(ENUM_ORDER_TYPE)HistoryOrderGetInteger(Ord_Tick,ORDER_TYPE);
            TypeStringOrd=EnumToString(OrdType);
            StringReplace(TypeStringOrd,"ORDER_TYPE_","");
            DataStringOrd= "    "+
                           IntegerToString(i)+"."+
                           HistoryOrderGetString(Ord_Tick,ORDER_SYMBOL)+" "+
                           TypeStringOrd+" ["+
                           IntegerToString(Ord_Tick)+"-"+
                           IntegerToString(HistoryOrderGetInteger(Ord_Tick,ORDER_MAGIC))+"-"+
                           DoubleToString(HistoryOrderGetDouble(Ord_Tick,ORDER_VOLUME_INITIAL),2)+"-"+
                           DoubleToString(HistoryOrderGetDouble(Ord_Tick,ORDER_PRICE_OPEN),
                                          (int)SymbolInfoInteger(HistoryOrderGetString(Ord_Tick,ORDER_SYMBOL),SYMBOL_DIGITS))+"]"+
                           "";
            ResetLastError();
            {if(!ObjectSetInteger(
                           0,                                  //Идентификатор чарта
                           sTXW,                               //Имя объекта
                           OBJPROP_TIME,                       //Изменяем координату времени объекта
                           gTime[0]
                         ))
            {
               Print("ObjectSetInteger2 Error=",GetLastError());
               continue;
            }}//if(!ObjectSetInteger(...
            ResetLastError();
            {if(!ObjectSetDouble(
                           0,                                  //Идентификатор чарта
                           sTXW,                               //Имя объекта
                           OBJPROP_PRICE,                      //Изменяем координату цены объекта
                           IndHeigh-11*(nRow+1)
                         ))
            {
               Print("ObjectSetDouble2 Error=",GetLastError());
               continue;
            }else{
               nRow++;
            }}//if(!ObjectSetDouble(...
            ObjectSetString(0,sTXW,OBJPROP_TEXT,DataStringOrd+"");
         }}//for(int i=History_Orders_Total-1;i>=0;i--)
      }}//if(History_Orders_Total>=0)
      //----- Запомним текущие счетчики
      History_Orders_Total_Old=History_Orders_Total;           //Закрытые рыночные ордера
      Sel_History_Orders_Total_Old=Sel_History_Orders_Total;   //Закрытые рыночные ордера отобранные
      //----- Инкремент счетчика колонок
      nColo++;
   }}//if(HistoryOrdersView)
//----- Список сделок в истории
   {if(HistoryDealsView)
   {
      History_Deals_Total=HistoryDealsTotal();                 //Совершенные сделки (выполненные ордера)
      Sel_History_Deals_Total=CalcHistoryDealsTotal(inSelectSym,inEliminatSym,SelSym,
                                                   inSelectMag,inEliminatMag,SelMag,
                                                   inSelectTick,inEliminatTick,SelTick);//Совершенные сделки (выполненные ордера) отобранные
      {if(Sel_History_Deals_Total!=Sel_History_Deals_Total_Old)//Пересчет - перерисовка при изменении количества
      {
         DeleteColo("LHD",History_Deals_Total_Old);            //Колонка истории позиций
         CreateColo("LHD",ColoStep*nColo,History_Deals_Total);
      }}//if(Sel_History_Deals_Total!=Sel_History_Deals_Total_Old)
      MoveColoLabel( "LHD",
                     ColoStep*nColo,
                     "History Dial="+
                     IntegerToString(Sel_History_Deals_Total)+"/"+
                     IntegerToString(History_Deals_Total)+
                     ((SummView)
                        ?(" ="+DoubleToString(CalcHistoryDealsSumm(  inSelectSym,inEliminatSym,SelSym,
                                                                     inSelectMag,inEliminatMag,SelMag,
                                                                     inSelectTick,inEliminatTick,SelTick),2)+" ")
                        :(""))+
                     ""   
                   );//Заголовок колонки
      //-----
      {if(History_Deals_Total>=0)
      {
         nRow=0;
         CopyTime(TheSymbol,PERIOD_CURRENT,(nFirstBar-(int)((ColoStep*nColo+ColoShift)*kScale)),1,gTime);
         {for(int i=History_Deals_Total-1;i>=0;i--)
         {
            sTXW="LHD_"+IntegerToString(i);                    //Устанавливаем имя для текcтового объекта
            ObjectSetString(0,sTXW,OBJPROP_TEXT," ");          //Обнуление строки вывода
            ulong Deal_Tick=HistoryDealGetTicket(i);           //Выбираем ордер по номеру в списке
            {if(Deal_Tick<=0){continue;}}                      //Неудачно - следующий
            {if(!CheckSym(HistoryDealGetString(Deal_Tick,DEAL_SYMBOL),inSelectSym,inEliminatSym,SelSym)){continue;}}//Не тот символ - следующий
            {if(!CheckMag(HistoryDealGetInteger(Deal_Tick,DEAL_MAGIC),inSelectMag,inEliminatMag,SelMag)){continue;}}//Проверка соответствия магика модели по критерию выбора
            {if(!CheckTick(HistoryDealGetInteger(Deal_Tick,DEAL_TICKET),inSelectTick,inEliminatTick,SelTick)){continue;}}//Проверка соответствия тикета модели по критерию выбора
            ENUM_DEAL_TYPE DealType=(ENUM_DEAL_TYPE)HistoryDealGetInteger(Deal_Tick,DEAL_TYPE);
            TypeStringDeal=EnumToString(DealType);
            StringReplace(TypeStringDeal,"DEAL_TYPE_","");
            DataStringDeal=  "    "+
                              IntegerToString(i)+"."+
                              HistoryDealGetString(Deal_Tick,DEAL_SYMBOL)+" "+
                              TypeStringDeal+" ["+
                              IntegerToString(Deal_Tick)+"-"+
                              IntegerToString(HistoryDealGetInteger(Deal_Tick,DEAL_MAGIC))+"-"+
                              DoubleToString(HistoryDealGetDouble(Deal_Tick,DEAL_VOLUME),2)+"-"+
                              DoubleToString(HistoryDealGetDouble(Deal_Tick,DEAL_PRICE),
                                             (int)SymbolInfoInteger(HistoryDealGetString(Deal_Tick,DEAL_SYMBOL),SYMBOL_DIGITS))+"]="+
                              DoubleToString(HistoryDealGetDouble(Deal_Tick,DEAL_PROFIT),2)+" "+
                              "";
            ResetLastError();
            {if(!ObjectSetInteger(
                           0,                                  //Идентификатор чарта
                           sTXW,                               //Имя объекта
                           OBJPROP_TIME,                       //Изменяем координату времени объекта
                           gTime[0]
                         ))
            {
               Print("ObjectSetInteger3 Error=",GetLastError());
               continue;
            }}//if(!ObjectSetInteger(...
            ResetLastError();
            {if(!ObjectSetDouble(
                           0,                                  //Идентификатор чарта
                           sTXW,                               //Имя объекта
                           OBJPROP_PRICE,                      //Изменяем координату цены объекта
                           IndHeigh-11*(nRow+1)
                         ))
            {
               Print("ObjectSetDouble3 Error=",GetLastError());
               continue;
            }else{
               nRow++;
            }}//if(!ObjectSetDouble(...
            ObjectSetString(0,sTXW,OBJPROP_TEXT,DataStringDeal+"");
         }}//for(int i=History_Deals_Total-1;i>=0;i--)
      }}//if(History_Deals_Total>=0)
      //----- Запомним текущие счетчики
      History_Deals_Total_Old=History_Deals_Total;             //Совершенные сделки (выполненные ордера)
      Sel_History_Deals_Total_Old=Sel_History_Deals_Total;     //Совершенные сделки (выполненные ордера) отобранные
      //----- Инкремент счетчика колонок
      nColo++;
   }}//if(HistoryDealsView)
//----- Формируем строку комментария на чарте
   {if(CommentView)
   {
      CommentLine[0]=""+
         "PositionsTotal="+IntegerToString(Positions_Total)+" "+
         "OrdersTotal="+IntegerToString(Orders_Total)+" "+
         "";
      CommentLine[1]=""+
         "HistoryOrdersTotal="+IntegerToString(History_Orders_Total)+" "+
         "HistoryDealsTotal="+IntegerToString(History_Deals_Total)+" "+
         "";
      Comment( CommentLine[0]+" "+CommentLine[1]+" "+
               (string)(datetime)(TimeCurrent()-ChartGetInteger(0,CHART_FIRST_VISIBLE_BAR,0)*PeriodSeconds(PERIOD_CURRENT))+" "+
               _n+"Ticks>>"+IntegerToString(gnTick)+" Tims>>"+IntegerToString(gnTimer));
   }}//if(CommentView)
//----- Перерисовка чарта
   ChartRedraw();
//-----
   return;
}//On_Tick()
//
//============================================================================================= MQL5 ===
//    On_Timer - Обработка событий по таймеру
//------------------------------------------------------------------------------------------------------
void On_Timer(){
//-----
   gnTimer++;
   {if(gnTimer>4294967000)
   {
      gnTimer=100;
   }}//if(gnTimer>4294967000)
   gInTimer=true;
   On_Tick();
}//On_Timer()