주시
1
0
포크
이미 MQLArticles을(를) 포크했습니다
0
원본 프로젝트 nique_372/MQLArticles
MQLArticles/PosMgmt/BE/Breakeven.mqh
Nique_372 Nique_372 1b2572d6ea
2026-11-06 10:40:44 -05:00
186 라인
8.3 KiB
MQL5
//+------------------------------------------------------------------+
//| Breakeven.mqh |
//| Copyright 2025, Niquel y Leo. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2025, Niquel y Leo."
#property link "https://www.mql5.com"
#property strict
#ifndef MQLARTICLES_POSMGMT_BE_BREAKEVEN_MQH
#define MQLARTICLES_POSMGMT_BE_BREAKEVEN_MQH
//+------------------------------------------------------------------+
//| Include |
//+------------------------------------------------------------------+
#include "Imp\\All.mqh"
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
namespace TSN
{
//+------------------------------------------------------------------+
//| CBreakEvenCreator class |
//+------------------------------------------------------------------+
//---
enum ENUM_TSNMQLART_BE_CREATOR_RES
{
TSNMQLART_BE_CREATOR_RES_OK,
TSNMQLART_BE_CREATOR_RES_INV_POINTER,
TSNMQLART_BE_CREATOR_RES_INVALID_PARAMS_SIZE,
TSNMQLART_BE_CREATOR_RES_ERR_INIT_BE,
};
//---
struct BreakEvenCreatorRes
{
CBreakEvenBase* ptr; // Ptr final
bool ok; // Ok o no
//---
BreakEvenCreatorRes(CBreakEvenBase* p, bool _ok)
: ptr(p), ok(_ok) {}
//---
static void FormatTrace(const TSNErrorFrame &trace[], int &trace_idx, string &out)
{
TSNSTD_ERRMAN_PUSHINI(out, trace_idx)
switch(trace[trace_idx].code)
{
case TSNMQLART_BE_CREATOR_RES_OK:
TSNSTD_ERRMAN_PUSHOUT(out, "Not error", trace_idx)
break;
case TSNMQLART_BE_CREATOR_RES_INV_POINTER:
TSNSTD_ERRMAN_PUSHOUT(out, StringFormat("Fatal failed created [betype=%s], by invalid pointer (creation)", EnumToString(ENUM_BREAKEVEN_TYPE(int(trace[trace_idx].info)))), trace_idx)
break;
case TSNMQLART_BE_CREATOR_RES_INVALID_PARAMS_SIZE:
{
const ulong v = trace[trace_idx].info;
TSNSTD_ERRMAN_PUSHOUT(out, StringFormat("Failed to create breakeven [type=%s], %d parameters were set but %d were expected",
EnumToString(ENUM_BREAKEVEN_TYPE(int(v & 0xffff))), int((v >> 16) & 0xffff), int(v >> 32)), trace_idx)
break;
}
case TSNMQLART_BE_CREATOR_RES_ERR_INIT_BE:
TSNSTD_ERRMAN_PUSHOUT(out, StringFormat("Failed initialize breakeven [type=%s], caused by:", EnumToString(ENUM_BREAKEVEN_TYPE(int(trace[trace_idx].info)))), trace_idx)
CBasicBEFormater::FormatTrace(trace, trace_idx, out);
break;
default:
TSNSTD_ERRMAN_PUSHOUT(out, "Unknow error", trace_idx)
break;
}
}
};
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
struct CBreakEvenCreator
{
private:
struct Params
{
BreakEvenParams params[];
};
Params m_parameters[BREAKEVEN_T_TOTAL];
public:
static CBreakEvenBase* CreateBreakEven(ENUM_BREAKEVEN_TYPE type, const string& sym, const ulong mag);
//--- Get
BreakEvenCreatorRes Create(ENUM_BREAKEVEN_TYPE type, const string& sym, const ulong mag);
//--- Set
void SetBeByFixedPoints(int points_be_, int extra_points_be_);
void SetBeByAtr(double atr_multiplier_be, double atr_multiplier_extra_be, CAtrOptimized* atr_ptr);
void SetBeByRR(double rr_a_put_the_break_even, ENUM_TYPE_EXTRA_BE_BY_RRR type_extra, double atr_multiplier_or_extra_points, CAtrOptimized* atr_ptr);
};
//+------------------------------------------------------------------+
//| Set rr with handle |
//+------------------------------------------------------------------+
void CBreakEvenCreator::SetBeByRR(double rr_a_put_the_break_even, ENUM_TYPE_EXTRA_BE_BY_RRR type_extra, double atr_multiplier_or_extra_points, CAtrOptimized * atr_ptr)
{
ArrayResize(m_parameters[(BREAKEVEN_TYPE_RR)].params, TSNMQLART_POSMGMT_BE_RR_NPARAMS);
m_parameters[BREAKEVEN_TYPE_RR].params[TSNMQLART_POSMGMT_BE_RR_I_COEF_RR].double_value = rr_a_put_the_break_even;
m_parameters[BREAKEVEN_TYPE_RR].params[TSNMQLART_POSMGMT_BE_RR_I_TYPEEXTRA].integer_value = (int)type_extra;
m_parameters[BREAKEVEN_TYPE_RR].params[TSNMQLART_POSMGMT_BE_RR_I_ATRMUL_OR_POINTS].double_value = atr_multiplier_or_extra_points;
m_parameters[BREAKEVEN_TYPE_RR].params[TSNMQLART_POSMGMT_BE_RR_I_ATRPTR].atr_pointer_value = atr_ptr;
}
//+------------------------------------------------------------------+
//| Set atr (with handle) |
//+------------------------------------------------------------------+
void CBreakEvenCreator::SetBeByAtr(double atr_multiplier_be, double atr_multiplier_extra_be, CAtrOptimized * atr_ptr)
{
ArrayResize(m_parameters[(BREAKEVEN_TYPE_ATR)].params, TSNMQLART_POSMGMT_BE_ATR_NPARAMS);
m_parameters[BREAKEVEN_TYPE_ATR].params[TSNMQLART_POSMGMT_BE_ATR_I_ATRPTR].atr_pointer_value = atr_ptr;
m_parameters[BREAKEVEN_TYPE_ATR].params[TSNMQLART_POSMGMT_BE_ATR_I_ATRMUL].double_value = atr_multiplier_be;
m_parameters[BREAKEVEN_TYPE_ATR].params[TSNMQLART_POSMGMT_BE_ATR_I_ATR_EMUL].double_value = atr_multiplier_extra_be;
}
//+------------------------------------------------------------------+
//| Set Fixed Point be |
//+------------------------------------------------------------------+
void CBreakEvenCreator::SetBeByFixedPoints(int points_be_, int extra_points_be_)
{
ArrayResize(m_parameters[(BREAKEVEN_TYPE_FIXED_POINTS)].params, TSNMQLART_POSMGMT_BE_BPOINTS_NPARMS);
m_parameters[BREAKEVEN_TYPE_FIXED_POINTS].params[TSNMQLART_POSMGMT_BE_BPOINTS_I_POINT_BE].integer_value = points_be_;
m_parameters[BREAKEVEN_TYPE_FIXED_POINTS].params[TSNMQLART_POSMGMT_BE_BPOINTS_I_EPOINT_BE].integer_value = extra_points_be_;
}
//+------------------------------------------------------------------+
//| Dynamically create the correct BreakEven |
//+------------------------------------------------------------------+
static CBreakEvenBase* CBreakEvenCreator::CreateBreakEven(ENUM_BREAKEVEN_TYPE type, const string& sym, const ulong mag)
{
switch(type)
{
case BREAKEVEN_TYPE_RR:
return new CBreakEvenRR(sym, mag);
case BREAKEVEN_TYPE_FIXED_POINTS:
return new CBreakEvenSimple(sym, mag);
case BREAKEVEN_TYPE_ATR:
return new CBreakEvenAtr(sym, mag);
default:
return NULL;
}
}
//+------------------------------------------------------------------+
//| Set Pointer |
//+------------------------------------------------------------------+
BreakEvenCreatorRes CBreakEvenCreator::Create(ENUM_BREAKEVEN_TYPE type, const string& sym, const ulong mag)
{
//---
CBreakEvenBase* obj = CreateBreakEven(type, sym, mag);
if(CheckPointer(obj) != POINTER_DYNAMIC)
return BreakEvenCreatorRes(NULL, CErrorTrace::FailInit<BreakEvenCreatorRes>(TSNMQLART_BE_CREATOR_RES_INV_POINTER, type));
//---
const uint params_expected = obj.m_num_params;
const uint params_size = m_parameters[type].params.Size();
if(params_size != params_expected)
{
delete obj;
return BreakEvenCreatorRes(NULL, CErrorTrace::FailInit<BreakEvenCreatorRes>(TSNMQLART_BE_CREATOR_RES_INVALID_PARAMS_SIZE,
ulong(type) | ulong(params_size) << 16 | ulong(params_expected) << 32));
}
//---
if(!obj.Set(m_parameters[type].params))
{
delete obj; // importante (antes se filtraba)
return BreakEvenCreatorRes(NULL, CErrorTrace::FailWrap<BreakEvenCreatorRes>(TSNMQLART_BE_CREATOR_RES_ERR_INIT_BE, type)); // Consecuencia de:
}
//---
return BreakEvenCreatorRes(obj, true);
}
//---
}
//+------------------------------------------------------------------+
#endif // MQLARTICLES_POSMGMT_BE_BREAKEVEN_MQH
//+------------------------------------------------------------------+