MQLArticles/Utils/FA/BarControler.mqh

//+------------------------------------------------------------------+
//|                                                 BarControler.mqh |
//|                                  Copyright 2025, Niquel Mendoza. |
//|                     https://www.mql5.com/es/users/nique_372/news |
//+------------------------------------------------------------------+
#property copyright "Copyright 2025, Niquel Mendoza."
#property link      "https://www.mql5.com/es/users/nique_372/news"
#property strict

#ifndef MQLARTICLES_UTILS_FA_BARCONTROLER_MQH
#define MQLARTICLES_UTILS_FA_BARCONTROLER_MQH

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
#include <TSN\\Time\\Main.mqh>
#include "Int\\Constant.mqh"
#include "..\\Tfi\\Base.mqh"

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
namespace TSN 
{
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
datetime CBarControlerNextTimeM(const datetime curr_time)
 {
//---
  int mon = CTimeUtils::Month(curr_time);
  int year = CTimeUtils::Year(curr_time);

//---
  mon++;
  if(mon > 12)
   {
    mon = 1;
    year++;
   }

//---
  return CTimeUtils::DateFrom(year,  mon, 1);
 }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
datetime CBarControlerNextTimeW(const datetime curr_time)
 {
  static MqlDateTime dt;
  CTimeUtils::TimeToStructFast(curr_time, dt);

//---
  const int days_from_monday = (dt.day_of_week == 0) ? 6 : dt.day_of_week - 1;
  return (curr_time - (days_from_monday * 86400) - (dt.hour * 3600) - (dt.min * 60) - dt.sec) + 604800;
 }

//+------------------------------------------------------------------+
//| Class to control the opening of a candle                         |
//+------------------------------------------------------------------+
class CBarControler
 {
private:
  datetime           next_time;
  datetime           prev_time;
  const ENUM_TIMEFRAMES    bar_timeframe;
  const int          period_in_seconds;
  const uint8_t      value;

public:
                     CBarControler(ENUM_TIMEFRAMES _timeframe);

  //---
  inline int         PeriodsInSeconds()          const { return period_in_seconds;  }
  inline             ENUM_TIMEFRAMES Timeframe() const { return bar_timeframe;      }
  inline datetime    GetNextPrevBarTime()        const { return prev_time;          }

  //---
  bool               IsNewBar(const datetime curr_time);
 };
//+------------------------------------------------------------------+
CBarControler::CBarControler(ENUM_TIMEFRAMES _timeframe)
  : next_time(wrong_datetime), prev_time(wrong_datetime), period_in_seconds(CTimeframe::PeriodSecondsFast(_timeframe)),
    bar_timeframe(_timeframe),
    value((_timeframe == PERIOD_W1 ? 1 : (_timeframe == PERIOD_MN1 ? 2 : 0)))
 {
 }

//+------------------------------------------------------------------+
bool CBarControler::IsNewBar(const datetime curr_time)
 {
  if(curr_time >= next_time)
   {
    prev_time = next_time;
    switch(value)
     {
      case 0:
        next_time = ((curr_time - (curr_time % period_in_seconds)) + period_in_seconds);
        break;
      case 1:
        next_time = CBarControlerNextTimeW(curr_time);
        break;
      case 2:
        next_time = CBarControlerNextTimeM(curr_time);
        break;
     }
    return true;
   }
  return false;
 }


//+------------------------------------------------------------------+
//| Clase general                                                    |
//+------------------------------------------------------------------+
class CBarControlerFast
 {
private:
  datetime           next_time;
  const int          period_in_seconds;
  const uint8_t      value;

public:
                     CBarControlerFast(ENUM_TIMEFRAMES _timeframe);

  //---
  __forceinline datetime NextTime()  const { return next_time; }

  //---
  bool               IsNewBar(const datetime curr_time);
 };
//+------------------------------------------------------------------+
CBarControlerFast::CBarControlerFast(ENUM_TIMEFRAMES _timeframe)
  : next_time(wrong_datetime), period_in_seconds(CTimeframe::PeriodSecondsFast(_timeframe)), 
   value((_timeframe == PERIOD_W1 ? 1 : (_timeframe == PERIOD_MN1 ? 2 : 0)))
 {
 }

//+------------------------------------------------------------------+
bool CBarControlerFast::IsNewBar(const datetime curr_time)
 {
  if(curr_time >= next_time)
   {
    switch(value)
     {
      case 0:
        next_time = ((curr_time - (curr_time % period_in_seconds)) + period_in_seconds);
        break;
      case 1:
        next_time = CBarControlerNextTimeW(curr_time);
        break;
      case 2:
        next_time = CBarControlerNextTimeM(curr_time);
        break;
     }
    return true;
   }
  return false;
 }


//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
class CBarControlerFastW1
 {
private:
  datetime           next_time;

public:
                     CBarControlerFastW1();
                    ~CBarControlerFastW1() {}

  //---
  __forceinline datetime NextTime()  const { return next_time; }

  //---
  bool               IsNewBar(const datetime curr_time);
 };
//+------------------------------------------------------------------+
CBarControlerFastW1::CBarControlerFastW1()
  : next_time(wrong_datetime)
 {
 }

//+------------------------------------------------------------------+
bool CBarControlerFastW1::IsNewBar(const datetime curr_time)
 {
  if(curr_time >= next_time)
   {
    next_time = CBarControlerNextTimeW(curr_time);
    return true;
   }
  return false;
 }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
class CBarControlerFastMN1
 {
private:
  datetime           next_time;

public:
                     CBarControlerFastMN1();
                    ~CBarControlerFastMN1() {}

  //---
  __forceinline datetime NextTime()  const { return next_time; }

  //---
  bool               IsNewBar(const datetime curr_time);
 };
//+------------------------------------------------------------------+
CBarControlerFastMN1::CBarControlerFastMN1()
  : next_time(wrong_datetime)
 {
 }

//+------------------------------------------------------------------+
bool CBarControlerFastMN1::IsNewBar(const datetime curr_time)
 {
  if(curr_time >= next_time)
   {
    next_time = CBarControlerNextTimeM(curr_time);
    return true;
   }
  return false;
 }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
class CBarControlerFastMinors
 {
private:
  datetime           next_time;
  const int          period_in_seconds;

public:
                     CBarControlerFastMinors(ENUM_TIMEFRAMES _timeframe);
                    ~CBarControlerFastMinors() {}

  //---
  __forceinline datetime NextTime()  const { return next_time; }

  //---
  bool               IsNewBar(const datetime curr_time);
 };
//+------------------------------------------------------------------+
CBarControlerFastMinors::CBarControlerFastMinors(ENUM_TIMEFRAMES _timeframe)
  : next_time(wrong_datetime), period_in_seconds(CTimeframe::PeriodSecondsFast(_timeframe))
 {
 }

//+------------------------------------------------------------------+
bool CBarControlerFastMinors::IsNewBar(const datetime curr_time)
 {
  if(curr_time >= next_time)
   {
    next_time = ((curr_time - (curr_time % period_in_seconds)) + period_in_seconds);
    return true;
   }
  return false;
 }
}

#endif // MQLARTICLES_UTILS_FA_BARCONTROLER_MQH
//+------------------------------------------------------------------+