| //+------------------------------------------------------------------+
|
| //| MACD.mq5 |
|
| //| Copyright 2000-2025, MetaQuotes Ltd. |
|
| //| https://www.mql5.com |
|
| //+------------------------------------------------------------------+
|
| #property copyright "Copyright 2000-2025, MetaQuotes Ltd."
|
| #property link "https://www.mql5.com"
|
| #property description "Moving Average Convergence/Divergence"
|
| #include <MovingAverages.mqh>
|
| //--- indicator settings
|
| #property indicator_separate_window
|
| #property indicator_buffers 4
|
| #property indicator_plots 2
|
| #property indicator_type1 DRAW_HISTOGRAM
|
| #property indicator_type2 DRAW_LINE
|
| #property indicator_color1 clrSilver
|
| #property indicator_color2 clrRed
|
| #property indicator_width1 2
|
| #property indicator_width2 1
|
| #property indicator_label1 "MACD"
|
| #property indicator_label2 "Signal"
|
| //--- input parameters
|
| input int InpFastEMA=12; // Fast EMA period
|
| input int InpSlowEMA=26; // Slow EMA period
|
| input int InpSignalSMA=9; // Signal SMA period
|
| input ENUM_APPLIED_PRICE InpAppliedPrice=PRICE_CLOSE; // Applied price
|
| //--- indicator buffers
|
| double ExtMacdBuffer[];
|
| double ExtSignalBuffer[];
|
| double ExtFastMaBuffer[];
|
| double ExtSlowMaBuffer[];
|
|
|
| int ExtFastMaHandle;
|
| int ExtSlowMaHandle;
|
| //+------------------------------------------------------------------+
|
| //| Custom indicator initialization function |
|
| //+------------------------------------------------------------------+
|
| void OnInit()
|
| {
|
| //--- indicator buffers mapping
|
| SetIndexBuffer(0,ExtMacdBuffer,INDICATOR_DATA);
|
| SetIndexBuffer(1,ExtSignalBuffer,INDICATOR_DATA);
|
| SetIndexBuffer(2,ExtFastMaBuffer,INDICATOR_CALCULATIONS);
|
| SetIndexBuffer(3,ExtSlowMaBuffer,INDICATOR_CALCULATIONS);
|
| //--- sets first bar from what index will be drawn
|
| PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,InpSignalSMA-1);
|
| //--- name for indicator subwindow label
|
| string short_name=StringFormat("MACD(%d,%d,%d)",InpFastEMA,InpSlowEMA,InpSignalSMA);
|
| IndicatorSetString(INDICATOR_SHORTNAME,short_name);
|
| //--- get MA handles
|
| ExtFastMaHandle=iMA(NULL,0,InpFastEMA,0,MODE_EMA,InpAppliedPrice);
|
| ExtSlowMaHandle=iMA(NULL,0,InpSlowEMA,0,MODE_EMA,InpAppliedPrice);
|
| }
|
| //+------------------------------------------------------------------+
|
| //| Moving Averages Convergence/Divergence |
|
| //+------------------------------------------------------------------+
|
| int OnCalculate(const int rates_total,
|
| const int prev_calculated,
|
| const datetime &time[],
|
| const double &open[],
|
| const double &high[],
|
| const double &low[],
|
| const double &close[],
|
| const long &tick_volume[],
|
| const long &volume[],
|
| const int &spread[])
|
| {
|
| if(rates_total<InpSignalSMA)
|
| return(0);
|
| //--- not all data may be calculated
|
| int calculated=BarsCalculated(ExtFastMaHandle);
|
| if(calculated<rates_total)
|
| {
|
| Print("Not all data of ExtFastMaHandle is calculated (",calculated," bars). Error ",GetLastError());
|
| return(0);
|
| }
|
| calculated=BarsCalculated(ExtSlowMaHandle);
|
| if(calculated<rates_total)
|
| {
|
| Print("Not all data of ExtSlowMaHandle is calculated (",calculated," bars). Error ",GetLastError());
|
| return(0);
|
| }
|
| //--- we can copy not all data
|
| int to_copy;
|
| if(prev_calculated>rates_total || prev_calculated<0)
|
| to_copy=rates_total;
|
| else
|
| {
|
| to_copy=rates_total-prev_calculated;
|
| if(prev_calculated>0)
|
| to_copy++;
|
| }
|
| //--- get Fast EMA buffer
|
| if(IsStopped()) // checking for stop flag
|
| return(0);
|
| if(CopyBuffer(ExtFastMaHandle,0,0,to_copy,ExtFastMaBuffer)<=0)
|
| {
|
| Print("Getting fast EMA is failed! Error ",GetLastError());
|
| return(0);
|
| }
|
| //--- get SlowSMA buffer
|
| if(IsStopped()) // checking for stop flag
|
| return(0);
|
| if(CopyBuffer(ExtSlowMaHandle,0,0,to_copy,ExtSlowMaBuffer)<=0)
|
| {
|
| Print("Getting slow SMA is failed! Error ",GetLastError());
|
| return(0);
|
| }
|
| //---
|
| int start;
|
| if(prev_calculated==0)
|
| start=0;
|
| else
|
| start=prev_calculated-1;
|
| //--- calculate MACD
|
| for(int i=start; i<rates_total && !IsStopped(); i++)
|
| ExtMacdBuffer[i]=ExtFastMaBuffer[i]-ExtSlowMaBuffer[i];
|
| //--- calculate Signal
|
| SimpleMAOnBuffer(rates_total,prev_calculated,0,InpSignalSMA,ExtMacdBuffer,ExtSignalBuffer);
|
| //--- OnCalculate done. Return new prev_calculated.
|
| return(rates_total);
|
| }
|
| //+------------------------------------------------------------------+
|
