dng/NN_in_Trading
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions
NN_in_Trading/Experts/FAT/Trajectory.mqh

1229 lines
77 KiB
MQL5
Raw Permalink Normal View History

new files added
2026-03-12 15:02:23 +02:00
<EFBFBD><EFBFBD>//+------------------------------------------------------------------+
//| Trajectory.mqh |
//| Copyright DNG<EFBFBD> |
//| https://www.mql5.com/ru/users/dng |
//+------------------------------------------------------------------+
#property copyright "Copyright DNG<00>"
#property link "https://www.mql5.com/ru/users/dng"
#property version "1.00"
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
#include "..\NeuroNet_DNG\NeuroNet.mqh"
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
input group "---- Indicators ----"
input ENUM_TIMEFRAMES TimeFrame = PERIOD_H1;
//---
input group "---- RSI ----"
input int RSIPeriod = 14; //Period
input ENUM_APPLIED_PRICE RSIPrice = PRICE_CLOSE; //Applied price
//---
input group "---- CCI ----"
input int CCIPeriod = 14; //Period
input ENUM_APPLIED_PRICE CCIPrice = PRICE_TYPICAL; //Applied price
//---
input group "---- ATR ----"
input int ATRPeriod = 14; //Period
//---
input group "---- MACD ----"
input int FastPeriod = 12; //Fast
input int SlowPeriod = 26; //Slow
input int SignalPeriod = 9; //Signal
input ENUM_APPLIED_PRICE MACDPrice = PRICE_CLOSE; //Applied price
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
int iLatentLayer = -1;
//---
#define HistoryBars 5
#define LongPeriod 7 //must be HistoryBars % Segments == 0
#define ShortPeriod 24 //must be HistoryBars % Segments == 0
#define BarDescr 9 //Elements for 1 bar description
#define AccountDescr 13 //Account description
#define NActions 6 //Number of possible Actions
#define NRewards 1 //Number of rewards
#define NForecast 12 //Number of forecast
#define EtalonBalance 1e4
#define BatchSize 1e+5
#define NSkills 64
#define NScenarios 9
#define EmbeddingSize 16
#define Buffer_Size 31000
#define DiscFactor 0.8f
#define FileName "FAT"
#define SignalFile(agent) StringFormat("Signals\\Signal%d.csv",agent)
#define LatentCount 128
#define LatentLayer iLatentLayer
#define MaxSL 1000
#define MaxTP 1000
#define MaxReplayBuffer 500
#define StartTargetIteration 200000
#define STE_Multiplier 1.0f/2
#define ActorUpdate 2
#define TargetUpdate 21*24
#define tau 0.9f
#define NExperts 6
#define TopK 2
#define NHeads 8
#define StackSize 24*5
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
struct SState
{
float state[HistoryBars * BarDescr];
float account[AccountDescr - 4];
float action[NActions];
float rewards[NRewards];
//---
SState(void);
//---
bool Save(int file_handle);
bool Load(int file_handle);
//--- overloading
void operator=(const SState &obj)
{
ArrayCopy(state, obj.state);
ArrayCopy(account, obj.account);
ArrayCopy(action, obj.action);
ArrayCopy(rewards, obj.rewards);
}
};
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
SState::SState(void)
{
ArrayInitialize(state, 0);
ArrayInitialize(account, 0);
ArrayInitialize(action, 0);
ArrayInitialize(rewards, 0);
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool SState::Save(int file_handle)
{
if(file_handle == INVALID_HANDLE)
return false;
//---
int total = ArraySize(state);
if(FileWriteInteger(file_handle, total) < sizeof(int))
return false;
for(int i = 0; i < total; i++)
if(FileWriteFloat(file_handle, state[i]) < sizeof(float))
return false;
//---
total = ArraySize(account);
if(FileWriteInteger(file_handle, total) < sizeof(int))
return false;
for(int i = 0; i < total; i++)
if(FileWriteFloat(file_handle, account[i]) < sizeof(float))
return false;
//---
total = ArraySize(action);
if(FileWriteInteger(file_handle, total) < sizeof(int))
return false;
for(int i = 0; i < total; i++)
if(FileWriteFloat(file_handle, action[i]) < sizeof(float))
return false;
total = ArraySize(rewards);
if(FileWriteInteger(file_handle, total) < sizeof(int))
return false;
for(int i = 0; i < total; i++)
if(FileWriteFloat(file_handle, rewards[i]) < sizeof(float))
return false;
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool SState::Load(int file_handle)
{
if(file_handle == INVALID_HANDLE)
return false;
if(FileIsEnding(file_handle))
return false;
//---
int total = FileReadInteger(file_handle);
if(total != ArraySize(state))
return false;
//---
for(int i = 0; i < total; i++)
{
if(FileIsEnding(file_handle))
return false;
state[i] = FileReadFloat(file_handle);
}
//---
total = FileReadInteger(file_handle);
if(total != ArraySize(account))
return false;
//---
for(int i = 0; i < total; i++)
{
if(FileIsEnding(file_handle))
return false;
account[i] = FileReadFloat(file_handle);
}
//---
total = FileReadInteger(file_handle);
if(total != ArraySize(action))
return false;
//---
for(int i = 0; i < total; i++)
{
if(FileIsEnding(file_handle))
return false;
action[i] = MathMin(MathMax(FileReadFloat(file_handle), 0), 1);
}
//---
total = FileReadInteger(file_handle);
if(total != ArraySize(rewards))
return false;
//---
for(int i = 0; i < total; i++)
{
if(FileIsEnding(file_handle))
return false;
rewards[i] = FileReadFloat(file_handle);
}
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
struct STrajectory
{
SState States[Buffer_Size];
int Total;
float DiscountFactor;
bool CumCounted;
//---
STrajectory(void);
//---
bool Add(SState &state);
void CumRevards(void);
//---
bool Save(int file_handle);
bool Load(int file_handle);
};
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
STrajectory::STrajectory(void) : Total(0),
DiscountFactor(DiscFactor),
CumCounted(false)
{
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool STrajectory::Save(int file_handle)
{
if(file_handle == INVALID_HANDLE)
return false;
if(Total <= 0)
return true;
//---
if(!CumCounted)
CumRevards();
Total = MathMin((int)States.Size(), Total);
if(FileWriteInteger(file_handle, Total) < sizeof(int))
return false;
if(FileWriteFloat(file_handle, DiscountFactor) < sizeof(float))
return false;
for(int i = 0; i < Total; i++)
if(!States[i].Save(file_handle))
return false;
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool STrajectory::Load(int file_handle)
{
if(file_handle == INVALID_HANDLE)
return false;
//---
Total = FileReadInteger(file_handle);
if(FileIsEnding(file_handle) || Total >= ArraySize(States))
return false;
DiscountFactor = FileReadFloat(file_handle);
CumCounted = true;
//---
for(int i = 0; i < Total; i++)
if(!States[i].Load(file_handle))
return false;
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
void STrajectory::CumRevards(void)
{
if(CumCounted)
return;
//---
for(int i = Total - 2; i >= 0; i--)
for(int r = 0; r < NRewards; r++)
States[i].rewards[r] += States[i + 1].rewards[r] * DiscountFactor;
CumCounted = true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool STrajectory::Add(SState &state)
{
if(Total + 1 >= ArraySize(States))
return false;
States[Total] = state;
Total++;
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
#ifndef StudyOnline
bool SaveTotalBase(void)
{
int total = ArraySize(Buffer);
if(total < 0)
return true;
int handle = FileOpen(FileName + ".bd", FILE_WRITE | FILE_BIN | FILE_COMMON);
if(handle < 0)
return false;
int start = MathMax(total - MaxReplayBuffer, 0);
if(FileWriteInteger(handle, total - start) < INT_VALUE)
{
FileClose(handle);
return false;
}
for(int i = start; i < total; i++)
if(!Buffer[i].Save(handle))
{
FileClose(handle);
return false;
}
FileFlush(handle);
FileClose(handle);
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool LoadTotalBase(void)
{
int handle = FileOpen(FileName + ".bd", FILE_READ | FILE_BIN | FILE_COMMON | FILE_SHARE_READ);
if(handle < 0)
return false;
int total = FileReadInteger(handle);
if(total <= 0)
{
FileClose(handle);
return false;
}
if(ArrayResize(Buffer, total) < total)
{
FileClose(handle);
return false;
}
int load_false = 0;
for(int i = 0; i < total; i++)
if(!Buffer[i].Load(handle))
{
total = i;
break;
}
FileClose(handle);
//---
if(ArrayResize(Buffer, total) < total)
{
FileClose(handle);
return false;
}
//---
return total > 0;
}
#endif
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool CreateDescriptions(CArrayObj *&encoder,
CArrayObj *&stfs,
CArrayObj *&actor,
CArrayObj *&critic
)
{
//---
CLayerDescription *descr;
//---
if(!encoder)
{
encoder = new CArrayObj();
if(!encoder)
return false;
}
if(!stfs)
{
stfs = new CArrayObj();
if(!stfs)
return false;
}
if(!actor)
{
actor = new CArrayObj();
if(!actor)
return false;
}
if(!critic)
{
critic = new CArrayObj();
if(!critic)
return false;
}
//--- Encoder
encoder.Clear();
//--- Input layer
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
uint prev_count = descr.count = (HistoryBars * BarDescr);
descr.activation = None;
descr.optimization = ADAM;
if(!encoder.Add(descr))
{
delete descr;
return false;
}
iLatentLayer = 0;
//--- layer 1
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBatchNormOCL;
descr.count = prev_count;
descr.batch = BatchSize;
descr.activation = None;
descr.optimization = ADAM;
if(!encoder.Add(descr))
{
delete descr;
return false;
}
iLatentLayer++;
//--- layer 2
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronTransposeOCL;
descr.count = HistoryBars;
descr.window = BarDescr;
descr.batch = BatchSize;
descr.activation = None;
descr.optimization = ADAM;
if(!encoder.Add(descr))
{
delete descr;
return false;
}
iLatentLayer++;
//--- layer 3
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronFieldPatternEmbedding;
descr.count = BarDescr;
descr.window = HistoryBars;
descr.window_out = HistoryBars;
descr.layers = NExperts;
descr.step = TopK;
descr.batch = BatchSize;
descr.activation = SoftPlus;
descr.optimization = ADAM;
if(!encoder.Add(descr))
{
delete descr;
return false;
}
iLatentLayer++;
//--- layer 4
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronFieldAwareConv;
descr.count = BarDescr;
{
uint temp[] = {HistoryBars, // Inputs window
HistoryBars, // Outputs window
EmbeddingSize // Embedding size
};
if(ArrayCopy(descr.windows, temp) < (int)temp.Size())
return false;
}
descr.variables = NExperts;
descr.step = TopK;
descr.batch = BatchSize;
descr.activation = SoftPlus;
descr.optimization = ADAM;
if(!encoder.Add(descr))
{
delete descr;
return false;
}
iLatentLayer++;
//--- layer 5
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronResFlowLattice;
descr.variables = 4; //HTR points to Segment
descr.count = (NForecast + descr.variables - 1) / descr.variables; //LTR Forecast
descr.window = BarDescr * HistoryBars; //Dimension In
descr.window_out = EmbeddingSize; //Hidden dimension
descr.layers = 3; //LTR layers
descr.step = NExperts; //LTR candidates
descr.batch = BatchSize;
descr.activation = None;
descr.optimization = ADAM;
if(!encoder.Add(descr))
{
delete descr;
return false;
}
iLatentLayer++;
//---
uint window = descr.window;
uint count = descr.count * descr.variables;
//--- STFS
stfs.Clear();
//--- Input layer
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = (window * count);
descr.activation = None;
descr.optimization = ADAM;
if(!stfs.Add(descr))
{
delete descr;
return false;
}
//--- layer 1
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronSTFS;
{
uint temp[] = {window, // Chanels In
BarDescr // Chanels Out
};
if(ArrayCopy(descr.windows, temp) < (int)temp.Size())
return false;
}
{
uint temp[] = {count, // Units In
NForecast // Units Out
};
if(ArrayCopy(descr.units, temp) < (int)temp.Size())
return false;
}
descr.activation = TANH;
descr.optimization = ADAM;
if(!stfs.Add(descr))
{
delete descr;
return false;
}
//--- layer 2
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBatchNormOCL;
descr.count = NForecast * BarDescr;
descr.batch = BatchSize;
descr.activation = None;
descr.optimization = ADAM;
if(!stfs.Add(descr))
{
delete descr;
return false;
}
//--- Actor
actor.Clear();
//--- Input layer
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = AccountDescr;
descr.activation = None;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 1
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronMultiWindowsConvOCL;
descr.count = 1;
{
uint temp[] = {4, // Account
5, // Position
4 // Time
};
if(ArrayCopy(descr.windows, temp) < (int)temp.Size())
return false;
}
descr.window_out = EmbeddingSize;
descr.batch = BatchSize;
descr.activation = None;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 2
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronFieldAwareConv;
descr.count = 3;
{
uint temp[] = {EmbeddingSize, // Inputs window
EmbeddingSize, // Outputs window
EmbeddingSize // Embedding size
};
if(ArrayCopy(descr.windows, temp) < (int)temp.Size())
return false;
}
descr.variables = NExperts;
descr.step = TopK;
descr.batch = BatchSize;
descr.activation = SoftPlus;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 3
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronMHFAT;
{
uint temp[] = {EmbeddingSize, // Inputs window
EmbeddingSize, // Key Dimension
EmbeddingSize // Embedding size
};
if(ArrayCopy(descr.windows, temp) < (int)temp.Size())
return false;
}
descr.count = 3;
descr.step = NHeads; // Heads
descr.batch = 1e4;
descr.layers = NExperts; // Candidates
descr.variables = TopK; // Top-K
descr.activation = None;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 4
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronMHCrossFAT;
{
uint temp[] = {EmbeddingSize, // Inputs window
EmbeddingSize, // Key Dimension
window, // Cross window
EmbeddingSize // Embedding size
};
if(ArrayCopy(descr.windows, temp) < (int)temp.Size())
return false;
}
{
uint temp[] = {3, // Query units
count // Cross units
};
if(ArrayCopy(descr.units, temp) < (int)temp.Size())
return false;
}
descr.step = NHeads; // Heads
descr.batch = 1e4;
descr.layers = NExperts; // Candidates
descr.variables = TopK; // Top-K
descr.activation = None;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 5
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronSpikeConvBlock;
descr.count = 3;
descr.window = EmbeddingSize;
descr.step = EmbeddingSize;
descr.window_out = (LatentCount + 2) / 3;
descr.variables = 1;
descr.batch = BatchSize;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 6
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = LatentCount;
descr.activation = SoftPlus;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 7
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = 2 * NActions;
descr.activation = SIGMOID;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 8
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronVAEOCL;
descr.count = NActions;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 9
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronConvOCL;
descr.count = NActions / 3;
descr.window = 3;
descr.step = 3;
descr.window_out = 3;
descr.activation = SIGMOID;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- Critic
critic.Clear();
//--- Input layer
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = NActions;
descr.activation = None;
descr.optimization = ADAM;
if(!critic.Add(descr))
{
delete descr;
return false;
}
//--- layer 1
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronMHCrossFAT;
{
uint temp[] = {3, // Inputs window
EmbeddingSize, // Key Dimension
window, // Cross window
EmbeddingSize // Embedding size
};
if(ArrayCopy(descr.windows, temp) < (int)temp.Size())
return false;
}
{
uint temp[] = {NActions / 3, // Query units
count // Cross units
};
if(ArrayCopy(descr.units, temp) < (int)temp.Size())
return false;
}
descr.step = NHeads; // Heads
descr.batch = 1e4;
descr.layers = NExperts; // Candidates
descr.variables = TopK; // Top-K
descr.activation = None;
descr.optimization = ADAM;
if(!critic.Add(descr))
{
delete descr;
return false;
}
//--- layer 2
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronSpikeConvBlock;
descr.count = NActions / 3;
descr.window = 3;
descr.step = 3;
descr.window_out = EmbeddingSize;
descr.variables = 1;
descr.batch = BatchSize;
descr.optimization = ADAM;
if(!critic.Add(descr))
{
delete descr;
return false;
}
//--- layer 4
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronSpikeConvBlock;
descr.count = NActions / 3;
descr.window = EmbeddingSize;
descr.step = EmbeddingSize;
descr.window_out = EmbeddingSize;
descr.variables = 1;
descr.batch = BatchSize;
descr.optimization = ADAM;
if(!critic.Add(descr))
{
delete descr;
return false;
}
//--- layer 5
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
prev_count = descr.count = LatentCount;
descr.activation = SoftPlus;
descr.batch = BatchSize;
descr.optimization = ADAM;
if(!critic.Add(descr))
{
delete descr;
return false;
}
//--- layer 6
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
prev_count = descr.count = NRewards;
descr.activation = None;
descr.batch = BatchSize;
descr.optimization = ADAM;
if(!critic.Add(descr))
{
delete descr;
return false;
}
//---
return true;
}
#ifndef Study
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool IsNewBar(void)
{
static datetime last_bar = 0;
if(last_bar >= iTime(Symb.Name(), TimeFrame, 0))
return false;
//---
last_bar = iTime(Symb.Name(), TimeFrame, 0);
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool CloseByDirection(ENUM_POSITION_TYPE type)
{
int total = PositionsTotal();
bool result = true;
for(int i = total - 1; i >= 0; i--)
{
if(PositionGetSymbol(i) != Symb.Name())
continue;
if(PositionGetInteger(POSITION_TYPE) != type)
continue;
result = (Trade.PositionClose(PositionGetInteger(POSITION_TICKET)) && result);
}
//---
return result;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool TrailPosition(ENUM_POSITION_TYPE type, double sl, double tp)
{
int total = PositionsTotal();
bool result = true;
datetime time = TimeCurrent() - 5 * PeriodSeconds(TimeFrame);
//---
for(int i = 0; i < total; i++)
{
if(PositionGetSymbol(i) != Symb.Name())
continue;
if(PositionGetInteger(POSITION_TYPE) != type)
continue;
if(PositionGetInteger(POSITION_TIME_UPDATE) > time)
continue;
bool modify = false;
double psl = PositionGetDouble(POSITION_SL);
double ptp = PositionGetDouble(POSITION_TP);
switch(type)
{
case POSITION_TYPE_BUY:
if((sl - psl) >= Symb.Point())
{
psl = sl;
modify = true;
}
if(MathAbs(tp - ptp) >= Symb.Point())
{
ptp = tp;
modify = true;
}
break;
case POSITION_TYPE_SELL:
if((psl - sl) >= Symb.Point())
{
psl = sl;
modify = true;
}
if(MathAbs(tp - ptp) >= Symb.Point())
{
ptp = tp;
modify = true;
}
break;
}
if(modify)
result = (Trade.PositionModify(PositionGetInteger(POSITION_TICKET), psl, ptp) && result);
}
//---
return result;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool ClosePartial(ENUM_POSITION_TYPE type, double value)
{
if(value <= 0)
return true;
//---
for(int i = 0; (i < PositionsTotal() && value > 0); i++)
{
if(PositionGetSymbol(i) != Symb.Name())
continue;
if(PositionGetInteger(POSITION_TYPE) != type)
continue;
double pvalue = PositionGetDouble(POSITION_VOLUME);
if(pvalue <= value)
{
if(Trade.PositionClose(PositionGetInteger(POSITION_TICKET)))
{
value -= pvalue;
i--;
}
}
else
{
if(Trade.PositionClosePartial(PositionGetInteger(POSITION_TICKET), value))
value = 0;
}
}
//---
return (value <= 0);
}
#endif
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
vector<float> GetProbTrajectories(STrajectory &buffer[], double lambda)
{
ulong total = buffer.Size();
vector<float> result = vector<float>::Zeros(total);
vector<float> temp;
for(ulong i = 0; i < total; i++)
{
temp.Assign(buffer[i].States[0].rewards);
result[i] = temp.Sum();
if(!MathIsValidNumber(result[i]))
result[i] = -FLT_MAX;
}
float max_reward = result.Max();
//---
vector<float> sorted = result;
bool sort = true;
int iter = 0;
while(sort)
{
sort = false;
for(ulong i = 0; i < sorted.Size() - 1; i++)
if(sorted[i] > sorted[i + 1])
{
float temp = sorted[i];
sorted[i] = sorted[i + 1];
sorted[i + 1] = temp;
sort = true;
}
iter++;
}
//---
float min = result.Min() - 0.1f * MathAbs(max_reward);
if(max_reward > min)
{
float k = sorted.Percentile(80) - max_reward;
vector<float> multipl = MathExp(MathAbs(result - max_reward) / (k == 0 ? -1 : k));
result = (result - min) / (max_reward - min);
result = result / (result + lambda) * multipl;
result.ReplaceNan(0);
}
else
result.Fill(1);
result = result / result.Sum();
result = result.CumSum();
//---
return result;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
int SampleTrajectory(vector<float> &probability)
{
//--- check
ulong total = probability.Size();
if(total <= 0)
return -1;
//--- randomize
float rnd = float(MathRand() / 32767.0);
//--- search
if(rnd <= probability[0] || total == 1)
return 0;
if(rnd > probability[total - 2])
return int(total - 1);
int result = int(rnd * total);
if(probability[result] < rnd)
while(probability[result] < rnd)
result++;
else
{
if(result <= 0)
Sleep(0);
while(probability[result - 1] >= rnd)
result--;
}
//--- return result
return result;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
class CDeal : public CObject
{
public:
datetime OpenTime;
datetime CloseTime;
ENUM_POSITION_TYPE Type;
double Volume;
double OpenPrice;
double StopLos;
double TakeProfit;
double point;
//---
CDeal(void);
~CDeal(void) {};
//---
vector<float> Action(datetime current, double ask, double bid, int period_seconds);
};
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
void CDeal::CDeal(void) : OpenTime(0),
CloseTime(0),
Type(POSITION_TYPE_BUY),
Volume(0),
OpenPrice(0),
StopLos(0),
TakeProfit(0),
point(1e-5)
{
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
vector<float> CDeal::Action(datetime current, double ask, double bid, int period_seconds)
{
vector<float> result = vector<float>::Zeros(NActions);
if((OpenTime - period_seconds) > current || CloseTime <= current)
return result;
//---
switch(Type)
{
case POSITION_TYPE_BUY:
result[0] = float(Volume);
if(TakeProfit > 0)
result[1] = float((TakeProfit - ask) / (MaxTP * point));
if(StopLos > 0)
result[2] = float((ask - StopLos) / (MaxSL * point));
break;
case POSITION_TYPE_SELL:
result[3] = float(Volume);
if(TakeProfit > 0)
result[4] = float((bid - TakeProfit) / (MaxTP * point));
if(StopLos > 0)
result[5] = float((StopLos - bid) / (MaxSL * point));
break;
}
//---
return result;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
class CDeals
{
protected:
CArrayObj Deals;
public:
CDeals(void) { Deals.Clear(); }
~CDeals(void) { Deals.Clear(); }
//---
bool LoadDeals(string file_name, string symbol, double point);
vector<float> Action(datetime current, double ask, double bid, int period_seconds);
};
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool CDeals::LoadDeals(string file_name, string symbol, double point)
{
if(file_name == NULL || !FileIsExist(file_name, FILE_COMMON))
{
PrintFormat("File %s not exist", file_name);
return false;
}
if(symbol == NULL)
{
symbol = _Symbol;
point = _Point;
}
//---
ResetLastError();
int handle = FileOpen(file_name, FILE_READ | FILE_ANSI | FILE_CSV | FILE_COMMON, short(';'), CP_ACP);
if(handle == INVALID_HANDLE)
{
PrintFormat("Error of open file %s: %d", file_name, GetLastError());
return false;
}
FileSeek(handle, 0, SEEK_SET);
while(!FileIsEnding(handle))
{
string s = FileReadString(handle);
datetime open_time = StringToTime(s);
string type = FileReadString(handle);
double volume = StringToDouble(FileReadString(handle));
string deal_symbol = FileReadString(handle);
double open_price = StringToDouble(FileReadString(handle));
volume = MathMin(volume, StringToDouble(FileReadString(handle)));
datetime close_time = StringToTime(FileReadString(handle));
double close_price = StringToDouble(FileReadString(handle));
s = FileReadString(handle);
s = FileReadString(handle);
s = FileReadString(handle);
if(StringFind(deal_symbol, symbol, 0) < 0)
continue;
//---
ResetLastError();
CDeal *deal = new CDeal();
if(!deal)
{
PrintFormat("Error of create new deal object: %d", GetLastError());
return false;
}
deal.OpenTime = open_time;
deal.CloseTime = close_time;
deal.OpenPrice = open_price;
deal.Volume = volume;
deal.point = point;
if(type == "Sell")
{
deal.Type = POSITION_TYPE_SELL;
if(close_price < open_price)
{
deal.TakeProfit = close_price;
deal.StopLos = 0;
}
else
{
deal.TakeProfit = 0;
deal.StopLos = close_price;
}
}
else
{
deal.Type = POSITION_TYPE_BUY;
if(close_price > open_price)
{
deal.TakeProfit = close_price;
deal.StopLos = 0;
}
else
{
deal.TakeProfit = 0;
deal.StopLos = close_price;
}
}
//---
ResetLastError();
if(!Deals.Add(deal))
{
PrintFormat("Error of add new deal: %d", GetLastError());
return false;
}
}
//---
FileClose(handle);
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
vector<float> CDeals::Action(datetime current, double ask, double bid, int period_seconds)
{
vector<float> result = vector<float>::Zeros(NActions);
for(int i = 0; i < Deals.Total(); i++)
{
CDeal *deal = Deals.At(i);
if(!deal)
continue;
vector<float> action = deal.Action(current, ask, bid, period_seconds);
result[0] += action[0];
result[3] += action[3];
result[1] = MathMax(result[1], action[1]);
result[2] = MathMax(result[2], action[2]);
result[4] = MathMax(result[4], action[4]);
result[5] = MathMax(result[5], action[5]);
}
//---
return result;
}
//+------------------------------------------------------------------+
Reference in a new issue Copy permalink