koros0111/Warrior_EA
1
0
Fork 0
forked from animatedread/Warrior_EA
Code Pull requests Activity
Warrior_EA/references/MQL5/Experts/BAC/Trajectory.mqh

727 lines
42 KiB
MQL5
Raw Permalink Normal View History

fix(cl): stabilize network training with tighter limits, weight decay, and sign-agreement gate - Tighten MAX_WEIGHT from 1.0e6 to 100.0 to prevent unbounded weight growth. - Add MIN_ACTIVATION_DERIVATIVE (1e-4) to avoid zero gradients for saturated units. - Introduce WEIGHT_DECAY (0.01) to decouple decay from Adam updates. - Add MAX_WEIGHT_DELTA (0.1) to clamp per-step Adam updates and prevent overshoot. - Apply sign-agreement gate on weight updates in Adam kernel to only apply steps aligned with current gradient direction. - Fix tanh/sigmoid derivative calculations to use the new floor instead of hard-coded edge-case values.
2026-07-15 21:47:37 -04:00
<EFBFBD><EFBFBD>//+------------------------------------------------------------------+
//| Trajectory.mqh |
//| Copyright DNG<EFBFBD> |
//| https://www.mql5.com/en/users/dng |
//+------------------------------------------------------------------+
#property copyright "Copyright DNG<00>"
#property link "https://www.mql5.com/en/users/dng"
#property version "1.00"
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
#include "..\RL\FQF.mqh"
//---
#define HistoryBars 20 //Depth of history
#define BarDescr 9 //Elements for 1 bar description
#define AccountDescr 12 //Account description
#define NActions 6 //Number of possible Actions
#define Buffer_Size 6500
#define DiscFactor 0.99f
#define FileName "BAC"
#define LatentLayer 6
#define LatentCount 256
#define MaxSL 1000
#define MaxTP 1000
#define PoliticAdjust 1.0e-1f
#define MaxReplayBuffer 500
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
struct SState
{
float state[HistoryBars * BarDescr];
float account[AccountDescr - 4];
float action[NActions];
//---
SState(void);
//---
bool Save(int file_handle);
bool Load(int file_handle);
//--- overloading
void operator=(const SState &obj)
{
ArrayCopy(state, obj.state);
ArrayCopy(account, obj.account);
ArrayCopy(action, obj.action);
}
};
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
SState::SState(void)
{
ArrayInitialize(state, 0);
ArrayInitialize(account, 0);
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool SState::Save(int file_handle)
{
if(file_handle == INVALID_HANDLE)
return false;
//---
int total = ArraySize(state);
if(FileWriteInteger(file_handle, total) < sizeof(int))
return false;
for(int i = 0; i < total; i++)
if(FileWriteFloat(file_handle, state[i]) < sizeof(float))
return false;
//---
total = ArraySize(account);
if(FileWriteInteger(file_handle, total) < sizeof(int))
return false;
for(int i = 0; i < total; i++)
if(FileWriteFloat(file_handle, account[i]) < sizeof(float))
return false;
//---
total = ArraySize(action);
if(FileWriteInteger(file_handle, total) < sizeof(int))
return false;
for(int i = 0; i < total; i++)
if(FileWriteFloat(file_handle, action[i]) < sizeof(float))
return false;
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool SState::Load(int file_handle)
{
if(file_handle == INVALID_HANDLE)
return false;
if(FileIsEnding(file_handle))
return false;
//---
int total = FileReadInteger(file_handle);
if(total != ArraySize(state))
return false;
//---
for(int i = 0; i < total; i++)
{
if(FileIsEnding(file_handle))
return false;
state[i] = FileReadFloat(file_handle);
}
//---
total = FileReadInteger(file_handle);
if(total != ArraySize(account))
return false;
//---
for(int i = 0; i < total; i++)
{
if(FileIsEnding(file_handle))
return false;
account[i] = FileReadFloat(file_handle);
}
//---
total = FileReadInteger(file_handle);
if(total != ArraySize(action))
return false;
//---
for(int i = 0; i < total; i++)
{
if(FileIsEnding(file_handle))
return false;
action[i] = FileReadFloat(file_handle);
}
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
struct STrajectory
{
SState States[Buffer_Size];
float Revards[Buffer_Size];
int Total;
float DiscountFactor;
bool CumCounted;
//---
STrajectory(void);
//---
bool Add(SState &state, float reward);
void CumRevards(void);
//---
bool Save(int file_handle);
bool Load(int file_handle);
};
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
STrajectory::STrajectory(void) : Total(0),
DiscountFactor(DiscFactor),
CumCounted(false)
{
ArrayInitialize(Revards, 0);
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool STrajectory::Save(int file_handle)
{
if(file_handle == INVALID_HANDLE)
return false;
//---
if(!CumCounted)
CumRevards();
if(FileWriteInteger(file_handle, Total) < sizeof(int))
return false;
for(int i = 0; i < Total; i++)
{
if(!States[i].Save(file_handle))
return false;
if(FileWriteFloat(file_handle, Revards[i]) < sizeof(float))
return false;
}
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool STrajectory::Load(int file_handle)
{
if(file_handle == INVALID_HANDLE)
return false;
//---
Total = FileReadInteger(file_handle);
if(Total >= ArraySize(Revards))
return false;
CumCounted = true;
//---
for(int i = 0; i < Total; i++)
{
if(!States[i].Load(file_handle))
return false;
Revards[i] = FileReadFloat(file_handle);
}
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
void STrajectory::CumRevards(void)
{
if(CumCounted)
return;
//---
for(int i = Total - 2; i >= 0; i--)
Revards[i] += Revards[i + 1] * DiscountFactor;
CumCounted = true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool STrajectory::Add(SState &state, float reward)
{
if(Total + 1 >= ArraySize(Revards))
return false;
States[Total] = state;
if(Total > 0)
Revards[Total - 1] = reward;
Total++;
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool SaveTotalBase(void)
{
int total = ArraySize(Buffer);
if(total < 0)
return true;
int handle = FileOpen(FileName + ".bd", FILE_WRITE | FILE_BIN | FILE_COMMON);
if(handle < 0)
return false;
int start = MathMax(total - MaxReplayBuffer, 0);
if(FileWriteInteger(handle, total - start) < INT_VALUE)
{
FileClose(handle);
return false;
}
for(int i = start; i < total; i++)
if(!Buffer[i].Save(handle))
{
FileClose(handle);
return false;
}
FileFlush(handle);
FileClose(handle);
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool LoadTotalBase(void)
{
int handle = FileOpen(FileName + ".bd", FILE_READ | FILE_BIN | FILE_COMMON | FILE_SHARE_READ);
if(handle < 0)
return false;
int total = FileReadInteger(handle);
if(total <= 0)
{
FileClose(handle);
return false;
}
if(ArrayResize(Buffer, total) < total)
{
FileClose(handle);
return false;
}
for(int i = 0; i < total; i++)
if(!Buffer[i].Load(handle))
{
FileClose(handle);
return false;
}
FileClose(handle);
//---
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool CreateDescriptions(CArrayObj *actor, CArrayObj *critic, CArrayObj *autoencoder)
{
//---
CLayerDescription *descr;
//---
if(!actor)
{
actor = new CArrayObj();
if(!actor)
return false;
}
if(!critic)
{
critic = new CArrayObj();
if(!critic)
return false;
}
if(!autoencoder)
{
autoencoder = new CArrayObj();
if(!autoencoder)
return false;
}
//--- Actor
actor.Clear();
//--- Input layer
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
int prev_count = descr.count = (HistoryBars * BarDescr);
descr.activation = None;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 1
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBatchNormOCL;
descr.count = prev_count;
descr.batch = 1000;
descr.activation = None;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 2
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronConvOCL;
prev_count = descr.count = prev_count - 1;
descr.window = 2;
descr.step = 1;
descr.window_out = 8;
descr.activation = LReLU;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 3
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronConvOCL;
prev_count = descr.count = prev_count;
descr.window = 8;
descr.step = 8;
descr.window_out = 8;
descr.activation = LReLU;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 4
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = 256;
descr.optimization = ADAM;
descr.activation = LReLU;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 5
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
prev_count = descr.count = 128;
descr.activation = LReLU;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 6
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronConcatenate;
descr.count = LatentCount;
descr.window = prev_count;
descr.step = AccountDescr;
descr.optimization = ADAM;
descr.activation = SIGMOID;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 7
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = 256;
descr.activation = LReLU;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 8
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = 256;
descr.activation = LReLU;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 9
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = 2*NActions;
descr.activation = LReLU;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- layer 10
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronVAEOCL;
descr.count = NActions;
descr.optimization = ADAM;
if(!actor.Add(descr))
{
delete descr;
return false;
}
//--- Critic
critic.Clear();
//--- Input layer
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
prev_count = descr.count = LatentCount;
descr.activation = None;
descr.optimization = ADAM;
if(!critic.Add(descr))
{
delete descr;
return false;
}
//--- layer 1
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronConcatenate;
descr.count = LatentCount;
descr.window = prev_count;
descr.step = NActions;
descr.optimization = ADAM;
descr.activation = LReLU;
if(!critic.Add(descr))
{
delete descr;
return false;
}
//--- layer 2
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = LatentCount;
descr.activation = LReLU;
descr.optimization = ADAM;
if(!critic.Add(descr))
{
delete descr;
return false;
}
//--- layer 3
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = LatentCount;
descr.activation = LReLU;
descr.optimization = ADAM;
if(!critic.Add(descr))
{
delete descr;
return false;
}
//--- layer 4
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
descr.count = 1;
descr.optimization = ADAM;
descr.activation = None;
if(!critic.Add(descr))
{
delete descr;
return false;
}
//--- Autoencoder
autoencoder.Clear();
//--- Input layer
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
prev_count = descr.count = LatentCount;
descr.activation = None;
descr.optimization = ADAM;
if(!autoencoder.Add(descr))
{
delete descr;
return false;
}
//--- layer 1
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
prev_count = descr.count = prev_count / 2;
descr.optimization = ADAM;
descr.activation = LReLU;
if(!autoencoder.Add(descr))
{
delete descr;
return false;
}
//--- layer 2
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
prev_count = descr.count = prev_count / 2;
descr.activation = LReLU;
descr.optimization = ADAM;
if(!autoencoder.Add(descr))
{
delete descr;
return false;
}
//--- layer 3
if(!(descr = new CLayerDescription()))
return false;
descr.type = defNeuronBaseOCL;
prev_count = descr.count = 20;
descr.count = LatentCount;
descr.activation = LReLU;
descr.optimization = ADAM;
if(!autoencoder.Add(descr))
{
delete descr;
return false;
}
//--- layer 4
if(!(descr = new CLayerDescription()))
return false;
if(!(descr.Copy(autoencoder.At(2))))
{
delete descr;
return false;
}
if(!autoencoder.Add(descr))
{
delete descr;
return false;
}
//--- layer 5
if(!(descr = new CLayerDescription()))
return false;
if(!(descr.Copy(autoencoder.At(1))))
{
delete descr;
return false;
}
if(!autoencoder.Add(descr))
{
delete descr;
return false;
}
//--- layer 6
if(!(descr = new CLayerDescription()))
return false;
if(!(descr.Copy(autoencoder.At(0))))
{
delete descr;
return false;
}
if(!autoencoder.Add(descr))
{
delete descr;
return false;
}
//---
return true;
}
#ifndef Study
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool IsNewBar(void)
{
static datetime last_bar = 0;
if(last_bar >= iTime(Symb.Name(), TimeFrame, 0))
return false;
//---
last_bar = iTime(Symb.Name(), TimeFrame, 0);
return true;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool CloseByDirection(ENUM_POSITION_TYPE type)
{
int total = PositionsTotal();
bool result = true;
for(int i = total - 1; i >= 0; i--)
{
if(PositionGetSymbol(i) != Symb.Name())
continue;
if(PositionGetInteger(POSITION_TYPE) != type)
continue;
result = (Trade.PositionClose(PositionGetInteger(POSITION_TICKET)) && result);
}
//---
return result;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool TrailPosition(ENUM_POSITION_TYPE type, double sl, double tp)
{
int total = PositionsTotal();
bool result = true;
//---
for(int i = 0; i < total; i++)
{
if(PositionGetSymbol(i) != Symb.Name())
continue;
if(PositionGetInteger(POSITION_TYPE) != type)
continue;
bool modify = false;
double psl = PositionGetDouble(POSITION_SL);
double ptp = PositionGetDouble(POSITION_TP);
switch(type)
{
case POSITION_TYPE_BUY:
if((sl - psl) >= Symb.Point())
{
psl = sl;
modify = true;
}
if(MathAbs(tp - ptp) >= Symb.Point())
{
ptp = tp;
modify = true;
}
break;
case POSITION_TYPE_SELL:
if((psl - sl) >= Symb.Point())
{
psl = sl;
modify = true;
}
if(MathAbs(tp - ptp) >= Symb.Point())
{
ptp = tp;
modify = true;
}
break;
}
if(modify)
result = (Trade.PositionModify(PositionGetInteger(POSITION_TICKET), psl, ptp) && result);
}
//---
return result;
}
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
bool ClosePartial(ENUM_POSITION_TYPE type, double value)
{
if(value <= 0)
return true;
//---
for(int i = 0; (i < PositionsTotal() && value > 0); i++)
{
if(PositionGetSymbol(i) != Symb.Name())
continue;
if(PositionGetInteger(POSITION_TYPE) != type)
continue;
double pvalue = PositionGetDouble(POSITION_VOLUME);
if(pvalue <= value)
{
if(Trade.PositionClose(PositionGetInteger(POSITION_TICKET)))
{
value -= pvalue;
i--;
}
}
else
{
if(Trade.PositionClosePartial(PositionGetInteger(POSITION_TICKET), value))
value = 0;
}
}
//---
return (value <= 0);
}
#endif
//+------------------------------------------------------------------+
Copy permalink