MQLArticles/Utils/File/FolderOps/FolderEncrypt.mqh
Nique_372 Nique_372 90c0f16c31
2026-10-22 21:57:02 -05:00
//+------------------------------------------------------------------+
//| FolderEncrypt.mqh |
//| Copyright 2026, Niquel Mendoza. |
//| https://www.mql5.com/es/users/nique_372 |
//+------------------------------------------------------------------+
#property copyright "Copyright 2026, Niquel Mendoza."
#property link "https://www.mql5.com/es/users/nique_372"
#property strict
#ifndef MQLARTICLES_UTILS_FILE_FOLDEROPS_FOLDERENCRYPT_MQH
#define MQLARTICLES_UTILS_FILE_FOLDEROPS_FOLDERENCRYPT_MQH
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
#include "Base.mqh"
#include <TSN\\Crypto\\Fernet.mqh>
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
namespace TSN
{
class CFolderOpsEncrypt : public CFolderOpsBase
{
private:
CFernet* m_fernet;
bool m_clean_all;
datetime m_time;
public:
CFolderOpsEncrypt(void) : m_fernet(NULL), m_clean_all(false), m_time(0) {}
~CFolderOpsEncrypt(void) {}
//---
void Fernet(CFernet* encryptor) { m_fernet = encryptor; }
CFernet* Fernet() { return m_fernet; }
//---
void SetInitialPass(datetime now) { m_clean_all = false; m_warns_s = 0; m_time = now; }
// Decrypt
void DecryptFolder(const string& init_dir, bool common_flag, bool delete_prev_file, int ttl, string ext_decrypt = NULL);
// Encrypt inline por bugs del compilador
template <typename TCryptoRandomFunc>
void EncryptFolder(const string& init_dir, bool common_flag, bool delete_prev_file, string ext_encrypt = NULL)
{
//---
string filename = "";
::ResetLastError();
//Print(init_dir);
long handle = FileFindFirst(init_dir + "*", filename, (common_flag ? FILE_COMMON : 0));
if(handle == INVALID_HANDLE)
{
FILEFOLDESOPS_PUSH_WARN(FILE_FOLDEROPS_WARN_NOT_FILE_FOLDER)
#ifdef MQLARTICLES_FOLDEROPS_ENABLE_LOGS
FastLog(FUNCION_ACTUAL, WARNING_TEXT, StringFormat("Error al comenzar la busqueda, ultimo error = %d, puede ser nomal si no hay archivos", ::GetLastError()));
#endif // MQLARTICLES_FOLDEROPS_ENABLE_LOGS
return;
}
//---
do
{
filename = init_dir + filename;
//---
if(filename[StringLen(filename) - 1] == '\\')
{
// a false dado qeu volveremos a llamar
//--- Buscamos si este folder esta en los arc hivos incluidos si lo esta entonces limpiamos todo sin exepcion
const bool p = m_clean_all;
if(IsFileIncluyed(filename))
m_clean_all = true;
//---
EncryptFolder<TCryptoRandomFunc>(filename, common_flag, delete_prev_file, ext_encrypt);
m_clean_all = p;
}
else
{
//---
if(!m_clean_all)
{
if(IsFileExcluyed(filename))
continue;
if(!IsFileIncluyed(filename))
continue;
}
//---
//Print(filename);
if(!m_fernet.EncryptFile<TCryptoRandomFunc>(filename, common_flag, delete_prev_file, m_time, ext_encrypt))
{
FILEFOLDESOPS_PUSH_WARN(FILE_FOLDEROPS_WARN_IN_EXE)
#ifdef MQLARTICLES_FOLDEROPS_ENABLE_LOGS
FastLog(FUNCION_ACTUAL, WARNING_TEXT, StringFormat("Fallo al encryptar el archivo = '%s', ultimo error = %d", filename, ::GetLastError()));
#endif // MQLARTICLES_FOLDEROPS_ENABLE_LOGS
}
}
}
while(FileFindNext(handle, filename));
//---
FileFindClose(handle);
}
};
//+------------------------------------------------------------------+
//| |
//+------------------------------------------------------------------+
void CFolderOpsEncrypt::DecryptFolder(const string& init_dir, bool common_flag, bool delete_prev_file, int ttl, string ext_decrypt = NULL)
{
//---
string filename = "";
::ResetLastError();
long handle = FileFindFirst(init_dir + "*", filename, (common_flag ? FILE_COMMON : 0));
if(handle == INVALID_HANDLE)
{
FILEFOLDESOPS_PUSH_WARN(FILE_FOLDEROPS_WARN_NOT_FILE_FOLDER)
#ifdef MQLARTICLES_FOLDEROPS_ENABLE_LOGS
FastLog(FUNCION_ACTUAL, WARNING_TEXT, StringFormat("Error al comenzar la busqueda, ultimo error = %d, puede ser nomal si no hay archivos", ::GetLastError()));
#endif // MQLARTICLES_FOLDEROPS_ENABLE_LOGS
return;
}
//---
do
{
filename = init_dir + filename;
//---
if(filename[StringLen(filename) - 1] == '\\')
{
// a false dado qeu volveremos a llamar
//--- Buscamos si este folder esta en los arc hivos incluidos si lo esta entonces limpiamos todo sin exepcion
const bool p = m_clean_all;
if(IsFileIncluyed(filename))
m_clean_all = true;
//---
DecryptFolder(filename, common_flag, delete_prev_file, ttl, ext_decrypt);
m_clean_all = p;
}
else
{
//---
if(!m_clean_all)
{
if(IsFileExcluyed(filename))
continue;
if(!IsFileIncluyed(filename))
continue;
}
//---
if(!m_fernet.DecryptFile(filename, common_flag, delete_prev_file, m_time, ttl, ext_decrypt))
{
FILEFOLDESOPS_PUSH_WARN(FILE_FOLDEROPS_WARN_IN_EXE)
#ifdef MQLARTICLES_FOLDEROPS_ENABLE_LOGS
FastLog(FUNCION_ACTUAL, WARNING_TEXT, StringFormat("Fallo al desencryptar el archivo = '%s', ultimo error = %d", filename, ::GetLastError()));
#endif // MQLARTICLES_FOLDEROPS_ENABLE_LOGS
}
}
}
while(FileFindNext(handle, filename));
//---
FileFindClose(handle);
}
}
//+------------------------------------------------------------------+
#endif // MQLARTICLES_UTILS_FILE_FOLDEROPS_FOLDERENCRYPT_MQH